AppleScript para conectar el Magic Mouse en el iMac

Parece que sabes cómo crear un sistema de Servicio o Acción rápida , y sólo necesita un script para abrir la conexión bluetooth real. Pruebe el script de abajo inicialmente en script Editor que requiere que cualquier dispositivo al que quieras conectarte ya haya sido emparejado (parece que este es el caso). Si todo va bien, puedes estar razonablemente seguro de que funcionará si lo traspasas a un Automatizador flujo de trabajo (si primero te deshaces de cualquier código de muestra que aparezca, es decir on run {input, parameters} etc.

use framework "Foundation"
use framework "IOBluetooth"

property this : a reference to the current application
property nil : a reference to missing value
property _1 : a reference to reference

property IOBluetoothDevice : a reference to IOBluetoothDevice of this
property NSPredicate : a reference to NSPredicate of this

property pairedDevices : a reference to IOBluetoothDevice's pairedDevices
property text item delimiters : linefeed & tab & "- "

to deviceWithName(name as text)
    local name
    NSPredicate's predicateWithFormat:"name==[c]%@" argumentArray:[name]
    tell filteredArrayUsingPredicate_(result) of pairedDevices
        if |count|() > 0 then return its firstObject()
        error {"No device by that name. Available devices:", ¬
            getDeviceNames() of me} as text
    end tell
end deviceWithName

to getDeviceNames()
    (pairedDevices's valueForKey:"name") as list
end getDeviceNames

try
    if deviceWithName("Magic Mouse 2")'s openConnection() ≠ 0 ¬
        then error "Could not open connection."
on error E
    return E
end try

true

NB. Este script sólo ha sido probado en High Sierra

Me temo que los mensajes de error no son especialmente comunicativos en caso de que algo no funcione como se espera. Pero, si el dispositivo puede conectar, el script debería gestionarlo. Si no se conecta, prueba que eres capaz de establecer una conexión manualmente.