No sé cómo cambiar el modo de vista por defecto para las nuevas listas de reproducción, pero puedes ejecutar un script como este en script Editor para cambiar el modo de vista de todas las listas de reproducción existentes:
tell application "iTunes"
user playlists whose special kind is none and smart is false
repeat with p in result
set view of browser window 1 to p
tell application "System Events" to tell process "iTunes"
click menu item "Songs" of menu 1 of menu item "View As" of menu 1 of menu bar item "View" of menu bar 1
end tell
end repeat
end tell
Utilizo un script como el siguiente para crear la mayoría de las nuevas listas de reproducción. Requiere GNU xargs y readlink que se puede instalar ejecutando brew install findutils coreutils .
osascript -e'on run {a}
set l to {}
repeat with f in (get paragraphs of a)
set end of l to POSIX file f
end repeat
tell application "iTunes"
if number of l is 1 then
tell application "Finder" to set n to name of (item 1 of l as alias)
delete playlists whose name is n
set p to make new user playlist with properties {name:n}
else
set p to make new user playlist
end if
with timeout of 0 seconds -- don't exit with an error if the add command takes over 20 seconds
add l to p
end
set view of browser window 1 to p
tell application "System Events" to tell process "iTunes"
click menu item "Songs" of menu 1 of menu item "View As" of menu 1 of menu bar item "View" of menu bar 1
end tell
end tell
end run' "$(printf %s\\n "${@-$(cat)}"|gxargs -rd\\n greadlink -f)"
Si la aplicación Eventos del sistema no está en la lista de aplicaciones en "Preferencias del sistema > Seguridad y privacidad > Privacidad > Accesibilidad", el script anterior da un error como este: 636:751: execution error: System Events got an error: osascript is not allowed assistive access. (-1719) .
