Cómo establecer la resolución de pantalla con un atajo de teclado en la Retina MBP?

Yo uso un AppleScript que cambia a través de las 3 de la 'escala' opciones dependiendo de la opción actual...

local index1, index2, index3

set index1 to 3 -- 1440 x 900 (Best for Retina)
set index2 to 4 -- 1680 x 1050
set index3 to 5 -- 1920 x 1200 (More Space)

-- Launch "System Preferences", open the "Displays" options and change to the "Display" tab
tell application "System Preferences"
    activate
    set the current pane to pane id "com.apple.preference.displays"
    reveal anchor "displaysDisplayTab" of pane id "com.apple.preference.displays"
end tell

local indexToUse

-- Now lets make the necessary changes
tell application "System Events"
    tell window "Color LCD" of application process "System Preferences" of application "System Events"
        tell tab group 1

            -- Click the "Scaled" radio button
            click radio button "Scaled"

            tell radio group 1 of group 1
                -- Depending on what scale option/index is current selected, set the appropriate new option/index to use
                if (value of radio button index1) is true then
                    set indexToUse to index2
                else if (value of radio button index2) is true then
                    set indexToUse to index3
                else
                    set indexToUse to index1
                end if

                -- Click the radio button for the new scale option/index
                click radio button indexToUse
            end tell

        end tell

        -- If option/index 1 is selected a warning prompt is displayed, click the OK button to dismiss the prompt
        if indexToUse = 1 then
            click button "OK" of sheet 1
        end if
    end tell
end tell

-- Quit "System Preferences"
quit application "System Preferences"

No tengo un MacBook Pro con una pantalla de Retina, por lo que es probable que tenga que cambiar los números de las filas. No sé si esto iba a funcionar con múltiples pantallas.

tell application "System Preferences"
    reveal anchor "displaysDisplayTab" of pane "com.apple.preference.displays"
end tell
tell application "System Events" to tell process "System Preferences"
    tell tab group 1 of window 1
        click radio button "scaled"
        tell table 1 of scroll area 1
            if selected of row 1 then
                set selected of row 2 to true
            else
                set selected of row 1 to true
            end if
        end tell
    end tell
end tell
quit application "System Preferences"

Usted puede dar a la secuencia de comandos de acceso directo con Alfred o FastScripts o mediante la creación de un Automator servicio.

Muy bien, entonces SwitchResX 4 parece ser capaz de hacer esto, en pocos y sencillos pasos.

1. Instalar SwitchResX 4 (Duh).
2. Lanzamiento de La SwitchResX 4 Panel de Preferencias, que debe verse como algo a continuación:
3. A partir de allí, ir a Display Sets, y agregar un nuevo grupo, que llamaremos Retina - Full Size, y asignarla a una combinación de teclas (en este caso, elegí opt + F1), y seleccione el tamaño completo de la resolución (1920 x 1200).
4. Crear un segundo grupo, que llamaremos Retina - Better Looking, y un mapa para la correcta resolución y claves (yo elegí 1600 x 1000 & opt + F2, respectivamente).
5. ???
6. La ganancia! Ya ha configurado SwitchResX poder de resolución del interruptor. (Nota: Este programa es shareware, y yo no soy asociada de ninguna manera con ella. Me encontré con él, mientras que haciendo una simple búsqueda en google).

Quicksilver puede hacerlo también si se habilita la Muestra plugin. Yo lo uso todo el tiempo. Puede asignar los desencadenantes específicos resoluciones/acciones así.

Ver también http://mac.appstorm.net/roundups/utilities-roundups/10-essential-quicksilver-plugins/ para una descripción rápida. Y aquí está la descripción de la ayuda:

Muestra Plugin
La muestra plugin permite Azogue para el índice de la muestra actualmente conectado a su Mac, con el fin de establecer el Escritorio la imagen y su resolución, profundidad de color y la frecuencia de actualización.

Véase también el Macbook Pro Retina de ejecución en resolución nativa