¿Cómo hacer que un enlace se abra en una ventana específica de Safari en MacOS?

Esto se puede hacer con una aplicación AppleScript que abre el enlace en Safari y hace que esta aplicación sea el navegador por defecto.

Durante las pruebas he encontrado dos versiones: abrir en nuevas ventanas o en nuevas pestañas si ya hay una ventana en el espacio actual.

• Abra script Editor.app (o incluso mejor script Depurador)

• Si quiere que los enlaces se abran en un nueva ventana utilice esto

  on open location theURL    
      tell application "Safari"  
          make new document with properties {URL:theURL}  
          activate  
      end tell  
  end open location  

• Si quiere que los enlaces se abran en un nueva pestaña (si se dispone de una ventana en el espacio actual) utilícela:

  on open location theURL  
      tell application "System Events"  
          tell process "Safari"  
              try  
                  set frontWinName to name of window 1 
              on error  
                  my openNewWindow(theURL)  
                  return  
              end try  
          end tell  
      end tell  
  
      tell application "Safari"  
          try  
              tell (first window whose name is frontWinName and miniaturized is false)  
                  set current tab to make new tab with properties {URL:theURL}  
                  activate  
              end tell  
          on error  
              my openNewWindow(theURL)  
          end try  
      end tell  
  end open location  
  
  on openNewWindow(theURL)  
      tell application "Safari"  
          make new document with properties {URL:theURL}  
          activate  
      end tell  
  end openNewWindow  

• Guardar como aplicación

• Si no quieres que la aplicación se muestre en el dock

  • Haz clic con el botón derecho del ratón en la aplicación, entra en el paquete y busca Info.plist

  • Añade esto Info.plist

    <key>LSUIElement</key>  
    <true/>

• Establecer la aplicación como navegador por defecto (He utilizado RCDefaultApp).

Si quieres ver lo molesto que es el comportamiento de los enlaces por defecto de MacOS te sugiero que vuelvas a cambiar a Safari como navegador por defecto después de algunas horas ...

Todavía estoy en 10.14.6 y no conozco las posibles restricciones en Catalina.

Como desarrollador, he investigado la posibilidad de que las extensiones puedan conseguir lo que quieres abriendo siempre un nuevo al hacer clic en un enlace contenido fuera del propio Safari. Siento decir que no creo que este enfoque sea posible.

Lamentablemente, Safari no ofrece a las extensiones una forma de determinar el origen de una nueva pestaña/ventana. Lo que quiero decir con esto es que una nueva pestaña puede crearse porque el usuario hace clic en un enlace en un correo electrónico, hace clic en un enlace en Safari, abre un marcador de Safari mientras mantiene pulsada la tecla Comando, hace clic en un enlace dentro de un documento PDF, o cualquier otra acción que abra una página en una nueva pestaña. Independientemente del método, Safari no proporciona cómo la ventana se abrió a una extensión de Safari.

Dado que todos estos eventos tienen el mismo aspecto, ninguna extensión puede forzar que los enlaces de fuera de Safari se abran en nuevas ventanas sin afectar también a los enlaces que se abren de otras formas (incluso mientras se navega dentro de Safari).

Aunque no se abre de forma nativa en la ventana deseada, siempre puedes coger la pestaña y recolocarla en otra ventana de Safari directamente después de que se haya abierto.

No sé si esto ayuda o no, sólo es una sugerencia.