Diferente comportamiento de las categorías en la GUI y en AppleScript

Tuve exactamente el mismo problema. Pude resolverlo aplicando el id de categoría exacto que quería como:

set end of theList to category id 33

Más que como:

set end of theList to category "Category1"

Así es como obtuve los identificadores de categoría. Seleccioné un mensaje en Outlook que tenía sólo la categoría que quería y luego ejecuté este script manualmente desde el script Editor:

tell application "Microsoft Outlook"

    set msgSet to current messages
    if msgSet = {} then
        error "No messages selected. Select at least one message."
        error -128
    end if

    repeat with aMessage in msgSet
        set theList to categories of aMessage
        return theList
    end repeat

end tell

A continuación, utilicé el identificador de categoría devuelto en el código siguiente para establecer los mensajes en esta categoría en el futuro (he improvisado esto a partir de muchas fuentes en línea a lo largo del tiempo, por lo que lamentablemente no es fácil para mí dar crédito a la gente adecuada):

tell application "Microsoft Outlook"

    -- Workaround for Outlook 2016 Reminders window bug, part 1
    set windowClosed to false
    if "Reminder" is in (name of the front window) then
        set windowClosed to true
        close front window
    end if

    set msgSet to current messages
    if msgSet = {} then
        error "No messages selected. Select at least one message."
        error -128
    end if

    repeat with aMessage in msgSet          
        set theList to categories of aMessage
        set end of theList to category id 33 -- CHANGE THIS TO THE CATEGORY ID RETURNED IN THE PREVIOUS SCRIPT
        set categories of aMessage to theList
    end repeat

    -- Workaround for Outlook 2016 Reminders window bug, part 2
    if windowClosed is true then
        tell application "System Events" to keystroke "9" using command down
    end if

end tell

Espero que esto ayude a alguien más que busque una solución para añadir una categoría a los correos electrónicos seleccionados de Outlook con AppleScript.

Una gran mejora sería eliminar el primer paso manual de obtener el id de la categoría deseada, y en su lugar permitir establecer la categoría a través del nombre textual de la misma, recorriendo todas las categorías existentes en Outlook hasta encontrarla, y entonces aplicando que id a los correos electrónicos seleccionados. Estaría agradecido si alguien mejorara mi versión de esta manera y la compartiera.