¿Cómo utilizar siempre el micrófono del macbook con el Bose QuietComfort 35?

No estoy seguro de lo práctico que es esto (no he tenido la oportunidad de medir el uso de la CPU, etc.), pero el siguiente AppleScript hará el trabajo-sólo tiene que reemplazar [YOUR HEADPHONES' NAME] con el nombre real de tus auriculares. Esta es una versión modificada de un script de un Hilo de las Comunidades de Soporte de Apple .

Guarde el script que aparece a continuación como una aplicación, ejecútelo y añádalo a sus elementos de inicio: debería ejecutarse continuamente en segundo plano.

repeat
    set statusOld to checkStatus()
    set statusNew to checkStatus()
    repeat while statusOld is equal to statusNew
        delay 5 --for 5 second checks
        set statusNew to checkStatus()
    end repeat
    if statusNew is true then
        tell application "System Preferences" to activate
        tell application "System Preferences"
            reveal anchor "input" of pane id "com.apple.preference.sound"
        end tell
        delay 0.5
        tell application "System Events" to tell process "System Preferences"
            tell table 1 of scroll area 1 of tab group 1 of window 1
                select (row 1 where value of text field 1 is "Internal Microphone")
            end tell
        end tell
        tell application "System Preferences" to quit
    else
        -- Nothing needs to happen, the device was removed
    end if
end repeat

on checkStatus()
    set bluetoothDeviceName to "[YOUR HEADPHONES' NAME]"
    set myString to do shell script "system_profiler SPBluetoothDataType"

    --initial check if it's not even there
    if myString does not contain bluetoothDeviceName then
        return false
    else

        --find out if connected/disconnected
        set AppleScript's text item delimiters to "name:"
        set myList to the text items of myString --each item of mylist is now one of the devices

        set numberOfDevices to count of myList
        set counter to 1
        repeat numberOfDevices times --loop through each devices checking for Connected string
            if item counter of myList contains bluetoothDeviceName then
                if item counter of myList contains "Connected: Yes" then
                    return true
                else if item counter of myList contains "Connected: No" then
                    return false
                else
                    display dialog "Something went wrong with the script" --this shouldn't happen
                end if
            end if
            set counter to counter + 1
        end repeat
    end if
end checkStatus

Se puede jugar con el tiempo entre comprobaciones (la línea con el comentario for 5 second checks ) para reducir el consumo de recursos.

Hay una serie de nuevas APIs (especialmente en AVFoundation ) que llega a macOS High Sierra y que permitiría una solución mucho más limpia a este problema. Si te sientes cómodo con Swift u Objective-C (o con el puente de scripting de Cocoa en AppleScript y JXA), yo miraría de usar esas APIs en lugar de este script una vez que High Sierra sea lanzado. En particular, la API de Apple Guía de programación de sesiones de audio y este post de Stack Overflow muestran algunas técnicas de detección de conexiones Bluetooth mediante AVAudioSession .