Cómo añadir una versión a un flujo de trabajo de servicio de Automator

El Info.plist es para aplicación se desea establecer una versión para un documento (flujo de trabajo, script, etc).

En un paquete de flujo de trabajo de Automator, el /Contenidos/documento.wflow es una lista de propiedades XML que declara las distintas acciones y su configuración (como el script para el Ejecutar AppleScript acción), conexiones de acción, metadatos de flujo de trabajo y variables. Esta lista de propiedades (o partes de ella) puede leerse en una lista o registro normal de AppleScript.

Posibles soluciones:

1. Se puede añadir una variable al flujo de trabajo. Las variables pueden ser establecidas dinámicamente por el flujo de trabajo, en cuyo caso sólo tendrán valores cuando el flujo de trabajo se ejecute, o pueden crearse variables más persistentes haciendo clic con el botón derecho del ratón en el panel de variables y editándolas (un par de las variables incorporadas pueden ser arrastradas al panel, pero necesitarían ser editadas de todos modos). Un script podría mirar el documento.wflow para el nombre de la variable en la lista de variables (habrá una clave de variables) y obtener su valor.

2. Se puede añadir un comentario en un Ejecutar AppleScript de la acción script. Esto funciona de forma similar a la adición de una variable, la diferencia es que un script tendría que buscar la acción en la lista de acciones (habrá una clave de acciones), obtener el script fuente de la acción, y luego buscar el comentario. No es mucho más difícil obtener el texto script, sólo que está enterrado un poco más profundo en la jerarquía (puedes comprobar la estructura de registros en el registro del editor script).

3. Añadir un archivo de texto que contenga la versión al paquete/paquete de documentos. Los archivos añadidos parecen no tener problemas, pero un par de desventajas son que habría otro archivo que editar, y la versión no sería aparente cuando se trabaje con el script o el flujo de trabajo.

4. Se puede añadir un atributo extendido al archivo, por ejemplo, /usr/bin/xattr -w com.myservice.version 2.9 /path/to/workflow . Esto también parece ser dejado solo, una (des)ventaja puede ser el uso de la Terminal o un shell script para leer y escribir el atributo.

Tenga en cuenta que el Finder no utiliza versiones para los documentos, y no conoce los atributos personalizados, por lo que nada de lo anterior aparecería en un Obtener información ventana.

El siguiente ejemplo utiliza el Suite de la lista de propiedades de Eventos del sistema para obtener listas de registros del archivo de listas de propiedades, que se utilizan para obtener el texto de la versión de una variable o el texto de script de un Ejecutar AppleScript acción (ajustar el nombre/texto como se desee):

on run -- example
   set plistFile to (choose file with showing package contents) -- get the document.wflow file
   # return scriptComment(plistFile) -- uncomment to use the script text
   return variableComment(plistFile)
end run

# Get version from a variable - the variable needs to be persistent (not generated by the workflow).
on variableComment(plistFile)
   tell application "System Events" to set variablesList to (get value of property list item "variables" of property list file (plistFile as text)) -- a record for each workflow variable
   if variablesList is not in {{}, missing value} then repeat with aRecord in variablesList
      try -- skip if no name or value key (built-in or not persistent)
         if |name| of aRecord is "Version" then -- or whatever
            return first item of value of aRecord -- the value is a list
         end if
      end try
   end repeat
   return missing value -- not found or no value
end variableComment

# Get version from script text - should be at the beginning of the first 'Run AppleScript' action.
on scriptComment(plistFile)
   tell application "System Events" to set actionsList to (get value of property list item "actions" of property list file (plistFile as text)) -- a record for each workflow action
   if actionsList is not in {{}, missing value} then repeat with aRecord in actionsList
      set theAction to action of aRecord -- base key
      if BundleIdentifier of theAction is "com.apple.Automator.RunScript" then
         repeat with aParagraph in paragraphs of (source of ActionParameters of theAction)
            if aParagraph contains "# Version" then -- or shebang, whatever
               return last word of aParagraph -- or wherever it is in the text
            end if
         end repeat
      end if
   end repeat
   return missing value -- not found or no value
end scriptComment