¿Cómo puedo buscar en el contenido de todo mi Terminal Windows

Terminal tienen dos útiles propiedades AppleScript llamadas history y contents .

contents contiene el contenido de texto de la pestaña actualmente visible en su panel (es decir, cualquier línea que se encuentre dentro de los límites de la parte visible la ventana).

history contiene todo el historial del contenido de la pestaña, desde el momento en que se creó hasta el momento en que se solicita el valor de la propiedad.

El comando AppleScript para recuperar todo el contenido (historial) de todas las pestañas de todas las ventanas actualmente abiertas en Terminal es:

    tell application "Terminal" to get the history of every tab of every window

Pero, como has descubierto, history puede contener una gran cantidad de datos de texto, dependiendo del número de pestañas que tenga abiertas y de su uso activo.

Su enfoque para resolver este problema es bueno: recorrer cada pestaña/ventana individualmente y manejar su contenido uno por uno.

Su AppleScript actual sólo recupera el contents de cada pestaña, que va a ser un subconjunto muy pequeño de los datos que contiene cada pestaña (que puede ser suficiente para sus necesidades). Si necesita tratar las cantidades más grandes de datos que contiene cada pestaña history propiedad, este podría ser un medio para hacerlo:

    set F to POSIX file "/Users/CK/Desktop/Terminal.txt"

    set _f to open for access F with write permission
    set eof _f to 0 -- Erase old contents

    tell application "Terminal"
        -- Loop through every window
        repeat with W in (a reference to windows)
            set [W] to W

            -- Loop through every tab of each window
            repeat with T in (tabs of W)
                set [T] to T

                set R to (a reference to history of T)
                write R & linefeed to _f
            end repeat
        end repeat

    end tell

    close access _f

Esto debería añadir secuencialmente el historial de texto de cada pestaña de cada ventana al archivo de texto especificado en la parte superior del script.