Has preguntado: "¿hay alguna forma de scribir la interfaz de usuario?". Sí, si estás en un Mac. También preguntaste, "¿alguien ha logrado hacer esto?" Más o menos. Mi historial se remonta a 2005, y la sesión de iTunes Store se desconectaba, así que tuve que ejecutarla por lotes, pero el siguiente script funciona. Ten en cuenta que se ejecuta muy lentamente; simplemente recuperar la clase de un objeto de iTunes puede tardar casi un segundo. Agradecería cualquier mejora de rendimiento que alguien pueda sugerir.
Esto funcionaba en OS X Yosemite 10.10.5 con iTunes 12.3.2.35, y en OS X Mavericks 10.9.5 con iTunes 12.3.2.35, en torno al 28 de febrero de 2016. Cualquier cambio que Apple haga en la interfaz de la cuenta de iTunes Store probablemente romperá este script.
En iTunes, vaya a Tienda > Ver cuenta, inicie sesión, desplácese hasta Historial de compras y haga clic en Ver todo, luego, cuando la pantalla que muestra Lote 1 de N sea visible, ejecute el siguiente scripten Editor:
tell application "System Events"
set dateString to do shell script "date \"+%Y-%m-%d_%H.%M.%S\""
log dateString
set target_file to ((path to documents folder) as text) & dateString & "_iTunes_Purchase_History.txt"
set myOutput to ""
set webArea to UI element "loading iTunes store" of splitter group 1 of window "iTunes" of application process "iTunes"
set batchText to value of first UI element of webArea whose value starts with "Viewing Batch"
log batchText
set AppleScript's text item delimiters to {" "}
set num to last text item in batchText
log num
set currentNum to text item 3 in batchText
log currentNum
repeat num times
set els to UI elements of webArea
set ready to false
set open_target_file to open for access file target_file with write permission
--repeat with el in els
repeat with el in els
set cl to class of el
if cl is button then
set myOutput to myOutput & "\n"
end if
if cl is static text then
set val to value of el
if val starts with "Copyright" then set ready to false
if ready then set myOutput to myOutput & val & "\t"
if val is "Total Price" then set ready to true
end if
end repeat
log myOutput
write myOutput to open_target_file starting at eof
set myOutput to ""
close access open_target_file
click button "Next" of webArea
repeat
delay 2
set batchText to value of first UI element of webArea whose value starts with "Viewing Batch"
set tempNum to text item 3 in batchText
if tempNum is not currentNum then
set currentNum to tempNum
log currentNum
exit repeat
end if
end repeat
delay 2
end repeat
end tell
Esto produce un texto delimitado por tabulaciones, no un CSV como pedía el OP, pero la mayoría de las aplicaciones de hojas de cálculo lo importarán. Las compras de regalos parecen estropear el formato, por lo que puede ser necesario un tratamiento manual.
Me basé en la información de http://n8henrie.com/2013/03/a-strategy-for-ui-scripting-in-applescript/ para aprender a hacer scripts GUI.
