Crear un servicio con Automator - Probado en MacOS Sierra

1. Abrir /Applications/Automator.app
2. Archivo > Nuevo (cmd-N)
   • Elija un tipo de documento: "Servicio".
3. El servicio recibe seleccionado: "archivos o carpetas" en el "Finder".
4. En el panel de la izquierda navegue a: Acciones > Biblioteca > Utilidades > Ejecutar AppleScript.
   • Arrastre el elemento "Ejecutar AppleScript" desde el panel de la biblioteca a la izquierda hasta el panel del código fuente a la derecha.
5. Borrar el contenido precargado por completo. Pegue el siguiente código fuente:

Código fuente de AppleScript

use framework "Foundation" -- Cocoa-AppleScript

on run {input, parameters}
    repeat with thisItem in input
        tell application "Finder"
            if kind of thisItem is "Alias" then -- alias file only
                set parentPath to container of thisItem -- get the folder of this alias
                set {label index:l, comment:c, modification date:m, creation date:cr, original item:origPath, name:n} to properties of (item thisItem)
                if origPath is not missing value then -- not a breaking alias
                    set tagsList to (my tagsFor:(POSIX path of thisItem)) -- get the tags of the alias file (call an AppleScriptObjC handler)
                    delete thisItem -- move this alias to the trash

                    -- ** create an alias file **
                    set newAliasFile to make new alias at parentPath to origPath with properties {comment:c, creation date:cr, original item:origPath, name:n}
                    -- ** set the label ** (0 = no label)
                    if l is not 0 then set label index of newAliasFile to l
                    -- ** set  the tags ** ({} = no tag) 
                    if tagsList is not {} then (my setTags:tagsList forPath:(POSIX path of (newAliasFile as string))) -- call an AppleScriptObjC handler
                    -- ** change the modification date **
                    set modification date of newAliasFile to m
                end if
            end if
        end tell
    end repeat
end run

on tagsFor:posixPath -- Cocoa-AppleScript handler 
    set fileURL to current application's |NSURL|'s fileURLWithPath:posixPath
    set {theResult, theTags} to fileURL's getResourceValue:(reference) forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
    if theTags = missing value then return {} -- no tags
    return theTags as list
end tagsFor:

on setTags:tagList forPath:posixPath -- Cocoa-AppleScript handler
    set fileURL to current application's |NSURL|'s fileURLWithPath:posixPath
    fileURL's setResourceValue:tagList forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
end setTags:forPath:

6. Archivo > Guardar (cmd-S): Dale un nombre como "Alias recreación".
7. Abre Preferencias del Sistema > Teclado > Accesos directos > Servicios > Archivos y carpetas > Recreación de alias, o como sea que lo hayas nombrado.
   • Asigna un acceso directo. Como cmd-L se utiliza para crear un alias (L como en "link"), le asigné cmd-alt-ctrl-L.
8. Seleccione uno o varios archivos de alias heredados y procéselos.
   • Con su atajo cmd-alt-ctrl-L.
   • o a través del menú principal: Finder > Servicios > Archivos y carpetas > Recreación de alias.

Nota : El proceso por lotes es muy transparente y se pueden corregir los errores. Los alias borrados se mueven a su papelera. Si ha cometido un error, elija el archivo de alias eliminado en cuestión y ejecute Finder > Volver a colocar (cmd-backspace). Esto devolverá el archivo a su carpeta principal anterior y abrirá la carpeta principal en una nueva ventana. Entonces tendrá el alias recreado y el alias original con el sufijo "copia" uno al lado del otro y podrá hacer correcciones si es necesario.