Cómo tomar capturas de pantalla en rápida sucesión

3 funciona tan rápido como puedo presionar en Big Sur 11.4 Beta 1 y no recuerdo haber tenido este problema en versiones anteriores de Big Sur.

Pruebe con una nueva cuenta de usuario para descartar interferencias de una aplicación en ejecución.

Supongo que puede resultarle útil.

El siguiente código de AppleScript tomará varias capturas de pantalla con un retraso de 0,01 segundos entre cada una.

Es de esperar que tenga conocimientos básicos de cómo utilizar AppleScript

 global captureCount, theCount
property theCounter : {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 20, 30, 50, 100}
property someName : "Screen Shot " -- Edit This To Desired Saved File Name
property delayInSeconds : 0.01 -- Edit To Desired Delay In Seconds For Screencaptures

activate
set captureCount to (choose from list theCounter ¬
    with title "Auto Screen Capture" with prompt ¬
    "Choose How Many Screenshots To Take" default items 5 ¬
    OK button name "OK" cancel button name "Cancel") as text as number

activate
set saveToFolder to (choose folder with prompt "Select A \"Save To\" Folder") as text

set theCount to 1

tell application "Finder"
    if alias (saveToFolder & someName & theCount & ".png") exists then
        repeat while alias (saveToFolder & someName & theCount & ".png") exists
            set theCount to theCount + 1
            delay 0.1
        end repeat
    end if
end tell

takeScreenShots(saveToFolder, someName, delayInSeconds)

on takeScreenShots(saveToFolder, someName, delayInSeconds)
    repeat captureCount times
        do shell script "screencapture -x " & quoted form of POSIX path ¬
            of (saveToFolder & someName & theCount & ".png")
        delay delayInSeconds
        set theCount to theCount + 1
    end repeat
end takeScreenShots

tell application "Finder"
    activate
    select alias saveToFolder
end tell