Responder automáticamente a los correos electrónicos con Mail, AppleScript y Automator

Puedes hacerlo así:

property the_numbers : {10000, 20000, 30000}
using terms from application "Mail"
    on perform mail action with messages theMessages for rule theRule
        repeat with i from 1 to count of theMessages
            tell application "Mail"
                set the_sender to sender of item i of theMessages
                set the_subject to subject of item i of theMessages
                set the_counter to item 1 of the_numbers
                -- make the outgoing message (the reply)
                set the_reply to make new outgoing message with properties ¬
                    {subject:"Re: " & the_subject, content:"Use this number-- " & the_counter}
                tell the_reply
                    make new to recipient at end of to recipients with properties {address:the_sender}
                end tell
                send the_reply
            end tell
            -- this is the step that deletes item 1 from the list 
            set the_numbers to items 2 thru -1 of the_numbers
        end repeat
    end perform mail action with messages
end using terms from

Esto funciona, pero tendrá que hacer un poco de trabajo para obtener su lista de números en una lista de AppleScript. Los pondrás al principio, separados por comas, sustituyendo a mis 10000, 20000, 30000.

Llamo a la lista de números "los_números". Al llamarla propiedad, guardamos el valor de los_números de una ejecución a otra. Si utilizas mi script tal cual en lugar de tu "Untitled 3" en la regla que has configurado, la primera vez que se llame al script estará trabajando con {10000, 20000, 30000}. La siguiente vez que se ejecute, la lista será {20000, 30000}. La próxima vez que se ejecute, será {30000}. También será {30000} para todas las ejecuciones posteriores. Estoy asumiendo/esperando que tienes una lista muy larga de números y no te vas a quedar sin ella.

Un mejor script permitiría saber que la lista de números se reduce al último.