Boot Camp no arranca después de clonar el disco

Veo dos problemas.

1. La tabla de particiones MBR del disco 1 tiene valores erróneos.
2. disk1s1 no pertenece y debe ser eliminado.

Voy a mostrar cómo solucionar el primer problema.

1. Abre la aplicación script Editor y abre una nueva ventana vacía. Las preferencias de preferencias muestran que estoy usando "script Editor (2.7)" y "AppleScript (2.4)" por defecto.

2. Pegue el siguiente código en la ventana.

   use scripting additions
   property disk : 1
   property mypassword : ""
   
   on fixmbr()
   
       script tm
           on subtract(x as text, y as text)
               return (x - y) as text
           end subtract
           on add(x as text, y as text)
               return (x + y) as text
           end add
       end script
   
       script mbr
           property table : {¬
               {id:"EE", guid:"C12A7328-F81F-11D2-BA4B-00A0C93EC93B"}, ¬
               {id:"07", guid:"EBD0A0A2-B9E5-4433-87C0-68B6B72699C7"}, ¬
               {id:"AF", guid:"48465300-0000-11AA-AA11-00306543ECAC"}, ¬
               {id:"AB", guid:"426F6F74-0000-11AA-AA11-00306543ECAC"}, ¬
               {id:"AC", guid:"53746F72-6167-11AA-AA11-00306543ECAC"}, ¬
               {id:"00", guid:"E3C9E316-0B5C-4DB8-817D-F92DF00215AE"}}
   
           property entry1 : {id:"00", active:"-", start:"0", size:"0"}
           property entry2 : {id:"00", active:"-", start:"0", size:"0"}
           property entry3 : {id:"00", active:"-", start:"0", size:"0"}
           property entry4 : {id:"00", active:"-", start:"0", size:"0"}
           property entry : {entry1, entry2, entry3, entry4}
   
           on MapGUIDToId(guid as text)
               repeat with pair in table
                   if guid is guid of pair then return id of pair
               end repeat
               log "error"
           end MapGUIDToId
           on MapIdToGUID(id as text)
               repeat with pair in table
                   if id is id of pair then return guid of pair
               end repeat
               log "error"
           end MapIdToGUID
       end script
   
       set output to do shell script "gpt -r show /dev/disk" & disk password mypassword with administrator privileges
   
       set AppleScript's text item delimiters to {" "} --, "GPT part -"}
       set i to 0
   
       set rows to paragraphs in output
       --showValue of sv for rows
       set foundActive to false
       set j to 0
       repeat with row in rows
   
           set columns to {}
           repeat with x in text items in row
               if x is not in {""} then
                   set end of columns to contents of x
               end if
           end repeat
   
           if length of columns is 7 and {"GPT", "part", "-"} is in columns then
               --showValue of sv for columns given minCount:12
               set i to i + 1
               set ind to (item 3 of columns) as integer
   
               if i is not equal to ind then
                   log "error"
               else if j is 0 and item 7 of columns is MapIdToGUID("EE") of mbr then
                   set j to 1
                   --log "found " & i & " for entry " & j
   
                   set partStart to item 1 of columns
                   set partSize to item 2 of columns
                   set partSize to add(partSize, partStart) of tm
                   set partStart to "1"
                   set partSize to subtract(partSize, partStart) of tm
   
                   set id of entry1 of mbr to "EE"
                   set start of entry1 of mbr to partStart
                   set size of entry1 of mbr to partSize
               else if 0 < j and j < 4 then
                   set j to j + 1
                   --log "found " & i & " for entry " & j
                   set entry to item j of entry of mbr
   
                   set id of entry to MapGUIDToId(item 7 of columns) of mbr
                   set start of entry to item 1 of columns
                   set size of entry to item 2 of columns
                   if not foundActive and id of entry is "07" then
                       set active of entry to "*"
                       set foundActive to true
                   end if
               end if
           end if
       end repeat
   
       set i to 0
       set input to {}
       repeat with ent in entry of mbr
           if id of ent is "00" then exit repeat
           set i to i + 1
           set end of input to "edit " & i & linefeed
           set end of input to id of ent & linefeed
           set end of input to "n" & linefeed
           set end of input to start of ent & linefeed
           set end of input to size of ent & linefeed
           if active of ent is "*" then
               set end of input to "flag " & i & linefeed
           end if
       end repeat
       set end of input to "q" & linefeed & "y" & linefeed
       set AppleScript's text item delimiters to {}
       set input to input as text
       --log linefeed & input
   
       set command to "fdisk -e /dev/disk" & disk & " << EOF" & linefeed & input & "EOF"
   
       log linefeed & command
   
       set output to do shell script command with administrator privileges
       log output
       display dialog "The script has finished." buttons {"OK"}
       return 0
   end fixmbr
   fixmbr()

3. Haz clic en el botón "Ejecutar". El script debería pedirte tu contraseña de acceso. Cuando el script termine, debería aparecer la siguiente ventana emergente emergente.

4. Salga del Editor de script e introduzca el siguiente comando en una ventana de Terminal de la terminal.

   sudo  fdisk  /dev/disk1

   El resultado debería ser el mismo que se muestra a continuación.

   Disk: /dev/disk1    geometry: 121601/255/63 [1953525168 sectors]
   Signature: 0xAA55
            Starting       Ending
    #: id  cyl  hd sec -  cyl  hd sec [     start -       size]
   ------------------------------------------------------------------------
    1: EE    0   0   2 - 1023 254  63 [         1 -     673791] <Unknown ID>
    2: AC 1023 254  63 - 1023 254  63 [    673792 - 1751953408] <Unknown ID>      
    3: AB 1023 254  63 - 1023 254  63 [1752627200 -    1269760] Darwin Boot     
   *4: 07 1023 254  63 - 1023 254  63 [1754306560 -  199217152] HPFS/QNX/AUX

Si todo ha funcionado, puedes salir de la aplicación Terminal e intentar arrancar Windows. Si Windows sigue sin arrancar, avísame y podemos intentar solucionar el segundo problema.

Expanación

Hay dos esquemas de partición que son importantes aquí. Son el Registro de arranque maestro (MBR) y el esquema de partición Identificador único global (GUID). El esquema MBR contiene un Tabla de partición MBR que permite definir sólo 4 particiones. El esquema GUID contiene las mismas 4 entradas Tabla de partición MBR y un Tabla de partición GUID (GPT) cuya longitud se determina en el momento de la creación. Este valor suele ser mucho mayor que 4 entradas.

Cuando un disco se particiona utilizando el esquema GUID, sólo se utiliza la primera entrada en la tabla MBR. En su disco, esta tabla contenía los siguientes datos.

Disk: /dev/disk1    geometry: 121601/255/63 [1953525168 sectors]
Signature: 0xAA55
         Starting       Ending
 #: id  cyl  hd sec -  cyl  hd sec [     start -       size]
------------------------------------------------------------------------
 1: EE    0   0   2 - 1023 254  63 [         1 - 1953525167] <Unknown ID>
 2: 00    0   0   0 -    0   0   0 [         0 -          0] unused      
 3: 00    0   0   0 -    0   0   0 [         0 -          0] unused      
 4: 00    0   0   0 -    0   0   0 [         0 -          0] unused      

El id de EE indica que el disco está particionado con GUID y que se debe utilizar el GPT para determinar el particionamiento. Las siguientes seis columas (Starting/Ending cyl/hd/sec) existen para propósitos de legado. La experiencia me ha enseñado que en los ordenadores Mac, no importa qué valores hay en estas seis columnas. En su caso, las tres primeras contienen los valores más bajos posibles válido y los tres siguientes contienen los valores más altos posibles válido valores. Lo importante son las columnas de inicio y tamaño. Tu disco está dividido en 1953525168 sectores donde cada sector tiene 512 bytes. El primer sector está numerado 0 y contiene el MBR que también contiene la tabla MBR. La partición con el id de EE se define para cubrir el resto del disco. Esto da la impresión de que todo el espacio ha sido asignado en el disco a los antiguos programas de particionamiento. Por eso verá la frase Registro maestro de protección de la bota (PMBR) en otra documentación.

A continuación se muestra una lista parcial del contenido de la GPT de su disco.

       start        size  index  contents
           0           1         PMBR
           1           1         Pri GPT header
           2          32         Pri GPT table
          34      262144      1  GPT part - E3C9E316-0B5C-4DB8-817D-F92DF00215AE
      262178        2014         
      264192      409600      2  GPT part - C12A7328-F81F-11D2-BA4B-00A0C93EC93B
      673792  1751953408      3  GPT part - 53746F72-6167-11AA-AA11-00306543ECAC
  1752627200     1269760      4  GPT part - 426F6F74-0000-11AA-AA11-00306543ECAC
  1753896960      409600         
  1754306560   199217152      5  GPT part - EBD0A0A2-B9E5-4433-87C0-68B6B72699C7
  1953523712        1423         
  1953525135          32         Sec GPT table
  1953525167           1         Sec GPT header

Cada entrada de la tabla tiene una longitud de 128 bytes. Como la tabla ocupa 32 sectores, se puede calcular que la tabla puede contener alrededor de 32 * 512 / 128 = 128 entradas. (En realidad, 128 es el valor por defecto según la documentación de la página man.) Tenga en cuenta que hay una tabla/cabecera de reserva al final del disco. Los GUID's corresponden a los siguientes tipos de particiones.

E3C9E316-0B5C-4DB8-817D-F92DF00215AE = Microsoft Reserved             
C12A7328-F81F-11D2-BA4B-00A0C93EC93B = EFI 
53746F72-6167-11AA-AA11-00306543ECAC = Apple_CoreStorage   
426F6F74-0000-11AA-AA11-00306543ECAC = Apple_Boot
EBD0A0A2-B9E5-4433-87C0-68B6B72699C7 = Microsoft Basic Data 

Normalmente, la aplicación Utilidad de Discos oculta el EFI y Apple_Boot particiones. El Microsoft Reservado La partición no pertenece y debe ser eliminada. El EFI la partición suele ser lo primero. No se utiliza para arrancar el sistema operativo OS X, pero es requerida por OS X para otros usos. El Apple_CoreStorage contiene la mayor parte de su volumen "Macintosh FD" de OS X. La dirección Apple_Boot partición (creo) contiene su "Partición de recuperación de arranque". El software, contenido en esta partición, es el reemplazo del software de recuperación que estaba en el DVD de instalación. Finalmente, Datos básicos de Microsoft contiene su volumen de Windows.

En tu Mac, Windows requiere un esquema MBR, lo que supone un conflicto ya que OS X utiliza un esquema GUID. Los siguientes cambios fueron necesarios en la tabla de particiones MBR para engañar a Windows para que piense que su ordenador está utilizando un esquema MBR.

1. El tamaño de la partición de EE se ajustó para cubrir justo el EFI partición.
2. Los datos se copiaron de la tabla de partición GPT a la MBR. Esto se hecho para las tres primeras particiones que siguieron a la EFI partición. En tu caso, se trata del resto de las particiones. El inicio y el tamaño fueron copiados exactamente. Cada GUID fue traducido a un id. Me gustaría daría una tabla de traducción, pero desafortunadamente no todas las traducciones son uno a uno.
3. La partición de Windows fue marcada como activa. Activo significa que se arranca en esta partición. Al imprimir la tabla de particiones MBR, la partición activa está marcada con un carácter *.

Una vez corregida, la tabla de particiones del MBR debería aparecer de la siguiente manera.

Disk: /dev/disk1    geometry: 121601/255/63 [1953525168 sectors]
Signature: 0xAA55
         Starting       Ending
 #: id  cyl  hd sec -  cyl  hd sec [     start -       size]
------------------------------------------------------------------------
 1: EE    0   0   2 - 1023 254  63 [         1 -     673791] <Unknown ID>
 2: AC 1023 254  63 - 1023 254  63 [    673792 - 1751953408] <Unknown ID>      
 3: AB 1023 254  63 - 1023 254  63 [1752627200 -    1269760] Darwin Boot     
*4: 07 1023 254  63 - 1023 254  63 [1754306560 -  199217152] HPFS/QNX/AUX

El comando que se utilizó para hacer los cambios en esta tabla en su disco se llama fdisk . Los valores para los cilindros/hd/seg de inicio/fin fueron elegidos por el comando. Aparte de marcar la partición 4 como activa, el script que ejecutó sólo introdujo los valores de id, inicio y tamaño.

Para ser más precisos, el comando exacto era sudo fdisk -e /dev/disk1 . Los comandos interactivos eran edit , flag y quit . Una descripción de fdisk se puede encontrar en este Página de OS X Man . (O escribiendo man fdisk en una ventana de Terminal).