¿Convertir el código HTML de las listas con viñetas en Markdown en AppleScript?

Lo siguiente ejemplo AppleScript código tal y como está codificado, está pensado para trabajar con lista con viñetas HTML código como se muestra en el OP lo que significa que lo que se pasa en el variable es sólo lo que corresponde código para definir el lista con viñetas y no otros arbitrarios HTML código .

Tal y como está codificado, producirá la salida adecuada para las variaciones de lista con viñetas HTML código también, no sólo el específico ejemplo que se muestra en este documento. Esto se ha probado en una variedad de otras muestras que contienen sólo lista con viñetas HTML código y produce la salida pertinente para ello al igual que el ejemplo aquí.

--  # Define exportedNote variable containing the bulleted list HTML code.

set exportedNote to "<ul>
  <li>Indent</li>
  <ul>
    <li>*Further* indent</li>
    <ul>
      <li>Even **further** indent. With a [link](https://duck.com).</li>
    </ul>
  </ul>
</ul>"

--  # Create an AppleScript list from the lines of bulleted list HTML code.

set exportedNoteList to paragraphs of exportedNote

--  # Process the list, acting only on items that contain "</li>" 
--  # as they are the only ones relevant to converting the 
--  # bulleted list HTML code to Markdown.

set tempList to {}
repeat with i from 1 to the number of items in exportedNoteList
    if item i of exportedNoteList contains "<li>" then
        set thisItem to item i of exportedNoteList
        set thisItem to findAndReplaceInText(thisItem, "</li>", "")
        set numberOfLeadingSpaces to ((offset of "<" in thisItem) - 1)
        if numberOfLeadingSpaces is less than 4 then
            set searchString to characters 1 thru numberOfLeadingSpaces of thisItem & "<li>" as text
            set thisItem to findAndReplaceInText(thisItem, searchString, "- ")
            set end of tempList to thisItem
        end if
        if numberOfLeadingSpaces is greater than 3 then
            set searchString to characters 1 thru numberOfLeadingSpaces of thisItem & "<li>" as text
            set thisItem to findAndReplaceInText(thisItem, searchString, "- ")
            set numberOfLeadingTabs to (numberOfLeadingSpaces / 2) as integer
            repeat with i from 1 to (numberOfLeadingTabs - 1)
                set thisItem to tab & thisItem
            end repeat
            set end of tempList to thisItem
        end if
    end if
end repeat

--  # Update the contents of the exportedNoteList
--  # list to contain only the relevant list items.

set exportedNoteList to tempList

--  # Convert the exportedNoteList list to text.

set AppleScript's text item delimiters to linefeed
set convertedNote to text items of exportedNoteList
set convertedNote to convertedNote as text
set AppleScript's text item delimiters to {}

--  # 'return' is only used to show its value in Script Editor. Use
--  # the convertedNote variable as needed in the working code.

return convertedNote

--  # Handler(s)

--  # Note: Handlers may be placed as one chooses as appropriate.
--  # My preference is at the bottom of the rest of the code.

on findAndReplaceInText(theText, theSearchString, theReplacementString)
    set AppleScript's text item delimiters to theSearchString
    set theTextItems to every text item of theText
    set AppleScript's text item delimiters to theReplacementString
    set theText to theTextItems as string
    set AppleScript's text item delimiters to ""
    return theText
end findAndReplaceInText

Resultado:

"- Indent
    - *Further* indent
        - Even **further** indent. With a [link](https://duck.com)."

Que se muestra como lo siguiente en un navegador en este sitio web:

• Indent
  • Más información en sangría
    • Incluso más sangría. Con un enlace .