AppleScript para pedir la entrada de la url, abrir la url en safari, luego abrir el marcador con un nombre específico

Me gustaría que el script pidiera al usuario que introdujera una url, entonces abrirá una nueva ventana con esta página y luego hará clic en el marcador que a su vez ejecutará algún JavaScript en la página abierta.

El ejemplo AppleScript código que se muestra a continuación, se probó en Script Editor en MacOS Catalina con Lengua y región ajustes en Preferencias del sistema ajustado a Inglés (EE.UU.) - Primaria y me ha funcionado sin problemas 1 .

• 1 _{Asume los ajustes necesarios y apropiados en <strong>Preferencias del sistema </strong>> <strong>Seguridad y privacidad </strong>> <strong>Privacidad </strong>se han fijado/abordado según las necesidades.}

Ejemplo AppleScript código :

set theURL to ""

repeat while theURL is ""
    set theURL to ¬
        the text returned of ¬
            (display dialog "Enter the URL:" default answer ¬
                "" buttons {"Cancel", "OK"} default button 2)
end repeat

tell application "Safari"
    activate
    make new document with properties {URL:theURL}
end tell

my waitForSafariPageToFinishLoading()

tell application "System Events" to ¬
    click menu item "Google" of ¬
        menu 1 of ¬
        menu bar item "Bookmarks" of ¬
        menu bar 1 of ¬
        application process "Safari"

--  # Handler #

to waitForSafariPageToFinishLoading()
    --  # Wait for page to finish loading in Safari.
    --  # This works in **macOS Catalina** and 
    --  # macOS Big Sur and may need adjusting for
    --  # other versions of macOS.
    tell application "System Events" to repeat until ¬
        exists (buttons of groups of toolbar 1 of window 1 of ¬
            process "Safari" whose name = "Reload this page")
        delay 0.5
    end repeat
end waitForSafariPageToFinishLoading

Notas:

Tengo un marcador que ejecuta un código JavaScript en el sitio web que el usuario tiene abierto en el momento de ejecutar el marcador.

El ejemplo AppleScript código hace exactamente lo que se pidió en la parte citada de la pregunta que aparece al principio de esta respuesta, sin embargo, la parte citada de la pregunta aparece al principio de esta Notas: sección No tengo forma de determinar lo que hace o si funciona o no, ya que no lo has incluido en un comentario bajo la pregunta. Por lo tanto, si lo que se presenta aquí no logra su objetivo usted está en su propia ya que no voy a responder más sin que usted proporciona toda la información solicitada.

_{Nota: El <em>ejemplo </em><strong>AppleScript </strong><em>código </em>es sólo eso y sin ningún tipo de inclusión <em>tratamiento de errores </em>no contiene ningún otro <em>tratamiento de errores </em>según corresponda. Corresponde al usuario añadir cualquier <em>tratamiento de errores </em>como sea apropiado, necesario o deseado. Eche un vistazo a la <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_control_statements.html#//apple_ref/doc/uid/TP40000983-CH6g-129232" rel="nofollow noreferrer"><strong>pruebe con </strong></a><em>declaración </em>y <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_control_statements.html#//apple_ref/doc/uid/TP40000983-CH6g-129657" rel="nofollow noreferrer"><strong>error </strong></a><em>declaración </em>en el <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/introduction/ASLR_intro.html" rel="nofollow noreferrer"><strong>Guía del lenguaje AppleScript </strong></a>. Véase también, <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_error_xmpls.html#//apple_ref/doc/uid/TP40000983-CH221-SW1" rel="nofollow noreferrer"><strong>Trabajar con errores </strong></a>. Además, el uso de la <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_cmds.html#//apple_ref/doc/uid/TP40000983-CH216-SW10" rel="nofollow noreferrer"><strong>retraso </strong></a><em>comando </em>puede ser necesario entre eventos cuando sea apropiado, por ejemplo <code>delay 0.5</code> con el <em>valor </em>de la <em>retraso </em>ajustado apropiadamente.}