¿Cómo puedo copiar la ubicación de una pista en la sección "Comentarios" de iTunes?

Porque se copia la ubicación en el Comments variable.

A continuación se explica cómo poner la ubicación en el comment etiqueta.

tell application "iTunes"
  tell track 1 of playlist "Test" to set comment to (its location as text)
  -- or set comment  of track 1 of playlist "Test" to (get location of track 1 of playlist "Test") as text
end tell

Esto debería servir:

tell application "iTunes"
    set theLocation to location of track 1 of playlist "Test"
    set the comment of track 1 of playlist "Test" to POSIX path of theLocation as string
end tell

El as string es la clave aquí, de lo contrario los tipos son incompatibles.

Si lo quieres como una línea, puedes hacerlo:

tell application "iTunes" to copy the POSIX path of (location of track 1 of playlist "Test" as string) to comment of track 1 of playlist "Test"

Si quieres las rutas al viejo estilo de Mac con dos puntos ( Macintosh HD:Users:rob:Music ) en lugar del estilo Unix ( /Users/rob/Music ), puede eliminar el POSIX path of partes de cualquiera de ellos.

Quería eliminar los directorios Root de la ruta, ejecutar en múltiples archivos, y saltar si ya hay algo en el campo, (y copiar a la descripción no a los comentarios), así que lo hice:

tell application "iTunes"
    if selection is not {} then -- there are tracks selected
        -- store current sort so we can fix during run
        set oldfi to fixed indexing
        set fixed indexing to true
        set mySelection to selection
        repeat with aTrack in mySelection
            -- if description empty
            set old_desc to ((get description of aTrack) as text)
            if old_desc is "" then
                -- get path of file
                set loc to POSIX path of ((get location of aTrack) as text)
                -- replace /Users/techtitch/Music/ with ~Music/
                set AppleScript's text item delimiters to "/Users/username/Music/"
                set the item_list to every text item of loc
                set AppleScript's text item delimiters to "~Music/"
                set loc to the item_list as string
                -- store path in description property of file
                set description of aTrack to loc
            end if
        end repeat
        -- restore prior sort
        set fixed indexing to oldfi
    end if
end tell

A continuación, sólo hay que guardar como /Users/username/Library/iTunes/Scripts/Copy selected files path to description.scpt (crear directorios si no están ya allí).

Crédito a dougscripts.com por la cartilla.