¿Borrar un archivo actualmente abierto directamente en la aplicación?

Prueba esto AppleScript en un servicio de Automator (puede asignar una tecla de acceso rápido a cualquier servicio):

on run
    set x to path to frontmost application as string
    tell application x to if exists document 1 then
        try
            try
                set p to path of front document -- some app use --> path of document
                p
            on error
                set p to file of front document -- some app use -->  file of document
            end try
            my moveToTrash(p)
            close front document
        on error
            my speakText("can't delete this document")
        end try
    else
        my speakText("You have no open document in that application")
    end if
end run

on moveToTrash(p)
    if p starts with "/" then -- some app return posix path
        set tFile to p as POSIX file as alias
    else -- some app return HFS path
        set tFile to p as alias
    end if
    tell application "Finder" to delete tFile
end moveToTrash

on speakText(t)
    say t
end speakText

He probado el script en estas aplicaciones ( "BBEdit", "TextWrangler", "TextEdit", "Preview" "QuickTime Player", "Pages", "Numbers", "Keynote", "Automator", "AppleScript Editor", "Xcode" ) en Mavericks

Este script no funcionará con algunas aplicaciones que no sean de Apple.

Para asignar una combinación de teclas al servicio recién creado:

Abra la aplicación Preferencias del Sistema y navegue hasta el panel de preferencias de Teclado, y seleccione la pestaña Atajos. En la lista de la izquierda del panel de preferencias, seleccione la categoría Servicios. A la derecha aparecerá una lista de los servicios instalados. Desplácese hasta la última categoría, titulada General, y localice el servicio que acaba de crear. Haga doble clic en el extremo derecho del nombre del servicio para activar el campo de entrada de teclas y, a continuación, escriba la combinación de teclas que desea asignar al servicio. Cierre la aplicación Preferencias del Sistema.