Applescript osacompile falla si la entrada del usuario contiene apóstrofe / comillas simples

Si estuviera haciendo algo así para mí, simplemente escribiría el contenido del "código" en un archivo temporal archivo de texto entonces usa osacompile para crear el AppleScript paquete de aplicaciones y a continuación borrar el archivo temporal archivo de texto . Haciéndolo de esta manera no debería tener que lidiar con el comillas simples pasó en un variable .

Lo siguiente ejemplo AppleScript código es sólo una prueba de concepto. En script Editor , sólo hay que establecer un valor para el smsNumber variable para usted, y luego ejecute el código .

Creará Foobar.app en su Escritorio para que luego Haga doble clic en y ver que le envía el mensaje con el comillas simples en él.

set appName to "Foobar"
set smsNumber to ""
set smsBody to "Here's my email"

set tempAppleScriptCode to ¬
    "/tmp/" & appName & ".applescript"

set saveToPathFileName to POSIX path of ¬
    (path to desktop as text) & appName & ".app"

set myAppleScriptCode to "tell application \"Messages\" 
    set imessageservice to 1st service whose service type = iMessage 
    set iMessageBuddy to buddy \"" & smsNumber & "\" of imessageservice 
    send \"" & smsBody & "\" to iMessageBuddy
end tell"

set tempFileWasWritten to ¬
    (my writeTextToFile(myAppleScriptCode, tempAppleScriptCode, true))

tell application "System Events" to ¬
    set saveToPathFileNameExists to ¬
        (exists item saveToPathFileName)

set saveToPathFileName to saveToPathFileName's quoted form
set tempAppleScriptCode to tempAppleScriptCode's quoted form

if tempFileWasWritten then
    if not saveToPathFileNameExists then
        do shell script "osacompile -o" & space & saveToPathFileName & ¬
            space & tempAppleScriptCode & ";rm" & space & tempAppleScriptCode
    else
        display dialog "The file '" & saveToPathFileName & ¬
            "' already exists!" buttons {"OK"} default button 1 ¬
            with title "The target file already exists!"
    end if
else
    display dialog "An error occured writing to: '" & tempAppleScriptCode & ¬
        "'" buttons {"OK"} default button 1 with title "Error writing to file!"
end if

on writeTextToFile(theText, theFile, overwriteExistingContent)
    try
        set theOpenedFile to open for access POSIX file theFile with write permission
        if overwriteExistingContent is true then set eof of theOpenedFile to 0
        write theText to theOpenedFile starting at eof
        close access theOpenedFile
        return true
    on error
        try
            close access file theFile
        end try
        return false
    end try
end writeTextToFile