Applescript: ¿Cómo guardar el texto a voz y convertirlo a mp3?

El comando say ha sido capaz de guardar en diferentes formatos durante un tiempo. Los formatos admitidos pueden variar con la voz, pero para Mei-Jia se guardará en mp3 o mp4 directamente, por lo que no necesitas hacer ninguna conversión o eliminación.

EDICIÓN: Parece que me equivoqué sobre la codificación - no hay un mp3, pero puedes usar el script de shell say para establecer otras codificaciones como mp4:

on run {input, parameters}
    set saveFolder to (((path to music folder) as text) & "Mandarin-text2speech:")
    repeat with thisText in input
        set fileName to getUniqueName for "audio.mp4" from saveFolder
        set output to quoted form of POSIX path of (saveFolder & fileName)
        do shell script "say -v 'Mei-Jia' -r 130 -o " & output & " --file-format=mp4f " & quoted form of thisText

    end repeat
end run

to getUniqueName for someName from someFolder -- añadir un sufijo numérico según sea necesario para obtener un nombre único
    set {divider, counter} to {"_", 0} -- el texto divisor y el número de sufijo inicial
    set leadingZeros to 2 -- máximos ceros principales
    set here to -(offset of "." in ((reverse of text items of someName) as text)) - 1 -- dividir la extensión en el último punto
    set theName to text 1 thru here of someName
    if here is -1 then -- no extensión
        set theExtension to ""
    else
        set theExtension to text (here + 1) thru -1 of someName
    end if

    if counter < 1 then -- siempre comenzar con un sufijo
        set counter to 1
        if leadingZeros > 0 then set counter to text -(leadingZeros + 1) thru -1 of ("000000" & counter)
        set newName to theName & divider & counter & theExtension
    else -- añadir sufijo según sea necesario
        set counter to counter - 1 -- ajustar para el bucle while
        set newName to theName & theExtension
    end if
    tell application "System Events" to tell (get name of items of folder (someFolder as text) whose visible is true)
        repeat while it contains newName
            set counter to counter + 1
            if leadingZeros > 0 then set counter to text -(leadingZeros + 1) thru -1 of ("000000" & counter)
            set newName to theName & divider & counter & theExtension
        end repeat
    end tell

    return newName
end getUniqueName