¿Buscar en todos los documentos abiertos de TextEdit?

Lo siguiente ejemplo AppleScript código cuando Ejecutar de script Editor o guardado como un AppleScript aplicación presentará un cuadro de diálogo de la cadena de búsqueda para que escriba en el cadena de búsqueda .

Si se encuentra una coincidencia, se crea un nuevo TextEdit documento con el nombre(s) de la documento(s) que contiene el cadena de búsqueda . Si no se encuentra ninguna coincidencia, se muestra un diálogo caja con un mensaje.

if running of application "TextEdit" then
    tell application "TextEdit"
        set docCount to count documents
        if docCount is greater than 0 then
            set searchString to ""
            repeat while searchString is ""
                set searchString to my getSearchString()
            end repeat
            set documentNamesList to {}
            repeat with i from 1 to docCount
                if text of document i contains the searchString then
                    copy name of document i to end of documentNamesList
                end if
            end repeat
            if documentNamesList is not {} then
                set AppleScript's text item delimiters to linefeed
                set documentNamesList to documentNamesList as string
                set AppleScript's text item delimiters to ""
                set docText to "The following TextEdit documents contain the search string: " & ¬
                    searchString & linefeed & linefeed & documentNamesList
                make new document with properties {text:docText}
                activate
            else
                display dialog "No documents found containing the search string: " & ¬
                    searchString buttons {"OK"} default button 1 with title "No Match Found"
            end if
        else
            display dialog "There are no open documents to search..." buttons {"OK"} ¬
                default button 1 with title "No Open Documents"
        end if
    end tell
else
    display dialog "TextEdit is not open..." buttons {"OK"} default button 1
end if

on getSearchString()
    return text returned of (display dialog ¬
        "Enter the search string:" default answer ¬
        "" buttons {"Cancel", "OK"} default button 2 ¬
        with title "Search Open TextEdit Documents")
end getSearchString

_{Nota: El <em>ejemplo </em><strong>AppleScript </strong><em>código </em>es sólo eso y no contiene ningún otro <em>tratamiento de errores </em>según corresponda. Corresponde al usuario añadir cualquier <em>tratamiento de errores </em>como sea apropiado, necesario o deseado. Eche un vistazo a la <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_control_statements.html#//apple_ref/doc/uid/TP40000983-CH6g-129232" rel="nofollow noreferrer"><strong>intente </strong></a><em>declaración </em>y <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_control_statements.html#//apple_ref/doc/uid/TP40000983-CH6g-129657" rel="nofollow noreferrer"><strong>error </strong></a><em>declaración </em>en el <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/introduction/ASLR_intro.html" rel="nofollow noreferrer"><strong>Guía del lenguaje AppleScript </strong></a>. Véase también, <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_error_xmpls.html#//apple_ref/doc/uid/TP40000983-CH221-SW1" rel="nofollow noreferrer"><strong>Trabajar con errores </strong></a>. Además, el uso del <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_cmds.html#//apple_ref/doc/uid/TP40000983-CH216-SW10" rel="nofollow noreferrer"><strong>retraso </strong></a><em>comando </em>puede ser necesario entre eventos cuando sea apropiado, por ejemplo <code>delay 0.5</code> con el <em>valor </em>de la <em>retraso </em>ajustado apropiadamente.}