Applescript, ¿cómo montar el servidor remoto sin error si no está disponible?

Utilizando un MacOS Catalina sistema como el servidor de archivos con /Users/Shared/Videos como SMB recurso compartido y habiendo hecho un poco de pruebas, encontré lo siguiente ejemplo AppleScript código para que funcione bien al hacer las pruebas con Script Editor de otro sistema en el red en la que el credenciales ya se han guardado en su Llavero :

set ipAddress to "172.16.15.141"
set sharedResource to "Videos"

if workgroupAvailable(ipAddress) then
    mount volume "smb://" & ipAddress & "/" & sharedResource
end if

on workgroupAvailable(ipAddress)
    set workGroup to do shell script ¬
        "smbutil status " & ipAddress & " | awk '/Workgroup:/{print $2}'"
    if workGroup is equal to "" then
        return false
    else
        return true
    end if
end workgroupAvailable

El responde de lo anterior ejemplo AppleScript código eran:

Cuando el recurso compartido no estaba disponible:

 tell current application
    do shell script "smbutil status 172.16.15.141 | awk '/Workgroup:/{print $2}'"
    --> ""
 end tell

Cuando el recurso compartido estaba disponible:

tell current application
    do shell script "smbutil status 172.16.15.141 | awk '/Workgroup:/{print $2}'"
        --> "WORKGROUP"
end tell
tell application "Script Editor"
    mount volume "smb://172.16.15.141/Videos"
        --> file "Videos:"
end tell
Result:
file "Videos:"

Lo que encontré con el uso de la smbutil status comando en curl que en mi red requería httpd que se ejecuta en el servidor y ping que podría responder incluso si el recurso compartido no estaba disponible, era que smbutil status no ha devuelto el Grupo de trabajo nombre si el recurso compartido no estaba disponible para ser montado y a su vez ningún intento de montar se produce si el Grupo de trabajo no está disponible.

Este ejemplo AppleScript código tampoco hizo aparecer ningún cuadro de diálogo en ningún momento cuando el recurso compartido no estaba disponible.

Tenga en cuenta que aunque las pruebas se hicieron con el reiniciando de la servidor de archivos e intentando conectar en varios momentos durante el reiniciar y el sistema realmente disponible, no he podido probar si el sistema se ha colgado durante el reinicio, ya que nunca se ha colgado durante ningún se reinicia . Como sé que este es un tema no resuelto con el reiniciando de su servidor Si lo desea, puede probarlo.

Evidentemente, se puede adaptar el ejemplo AppleScript código para satisfacer sus necesidades específicas.

_{Nota: El <em>ejemplo </em><strong>AppleScript </strong><em>código </em>es sólo eso y no contiene ningún <em>tratamiento de errores </em>según corresponda. Corresponde al usuario añadir cualquier <em>tratamiento de errores </em>como sea apropiado, necesario o deseado. Eche un vistazo a la <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_control_statements.html#//apple_ref/doc/uid/TP40000983-CH6g-129232" rel="nofollow noreferrer"><strong>intente </strong></a><em>declaración </em>y <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_control_statements.html#//apple_ref/doc/uid/TP40000983-CH6g-129657" rel="nofollow noreferrer"><strong>error </strong></a><em>declaración </em>en el <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/introduction/ASLR_intro.html" rel="nofollow noreferrer"><strong>Guía del lenguaje AppleScript </strong></a>. Véase también, <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_error_xmpls.html#//apple_ref/doc/uid/TP40000983-CH221-SW1" rel="nofollow noreferrer"><strong>Trabajar con errores </strong></a>. Además, el uso del <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_cmds.html#//apple_ref/doc/uid/TP40000983-CH216-SW10" rel="nofollow noreferrer"><strong>retraso </strong></a><em>comando </em>puede ser necesario entre eventos cuando sea apropiado, por ejemplo <code>delay 0.5</code> con el <em>valor </em>de la <em>retraso </em>ajustado apropiadamente.}

La forma más sencilla y portable de hacerlo sería a través del shell script. La razón es que evitar completamente los diálogos de error emergentes de la GUI que como has comprobado, rompe tu script. Es mejor manejarlos en el shell .

A continuación se muestra un muy corto script bash/zsh script para conectarse a un recurso compartido del servidor en particular. Puedes personalizarlo manipulando las variables de la parte superior. La clave aquí es almacenar la contraseña del usuario en el llavero para que se conecte sin problemas en todas las conexiones posteriores.

El script es en realidad bastante corto; puedes eliminar todo el printf ya que sólo los incluí para que saliera cada paso en la consola para su referencia. Como todos los comandos de Unix, sale con un 0 para una carrera exitosa y un 1 si hubiera algún problema.

n=1                        # initialize iteration variable
max=3                      # max number of attempts
cflag=1                    # initialize connection flag / 0=true; 1=false
sleeptime=5                # number of seconds to sleep between retries
svr="sername.example"      # server name/IP address
loc="Network Share"        # directory/folder location
user="JVC"                 # username which to authenticate with 

#### Code is Below ###

while [ ${n} -le 3 ] && [ ${cflag} -gt 0 ]    #While not connected and attempts < max
do
if  [ ! $(ping -c 1 ${svr}) ]; then
  printf "Attempt ${n}: Device ${svr} not ready. Sleeping for retry...\n"
  sleep ${sleeptime}
  n=$(( ${n} + 1 ))               # increase count
else 
  cflag=0                         # Set connection flag to "true"
  printf "Device found.  Connecting to "
  printf "smb://${user}@${svr}/${loc}.\n"
  open "smb://${user}@${svr}"     # Connect and mount the share
fi 
done

# Print error message and exit with appropriate exit code.
if [ ${n} -eq ${max} ]; then
  printf "Could not connect to ${svr} in ${n} tries. Giving up."
  exit 1
fi
exit 0

Me encontré con este problema hace algún tiempo, y mi solución fue usar curl de antemano para determinar si una dirección era accesible.

Haz una subrutina para comprobar si existe una dirección:

on addressExists(address)
    try
        do shell script "curl -I --connect-timeout 0.5 'http://" & address & "'" --will error if address does not exist
        return true
    on error
        return false
    end try
end addressExists

Entonces conéctate al servidor sólo si la subrutina dice que es accesible:

if addressExists(serverAddress) then
    tell application "Finder" to mount volume "smb://" & serverAddress
end if

Lo difícil aquí: notarás que el addressExists la subrutina anexa http:// al principio -como necesita curl- mientras que el script principalañade smb:// como necesita Finder. Asegúrese de que la variable de la dirección del servidor no contiene un protocolo.

Si sirve de ayuda, aquí está el proyecto más grande en el que utilicé esto: https://github.com/ideasonpurpose/NAS-Location-Sharing-Workflow

Nota de compatibilidad menor: este método funciona en 10.12 y superiores, pero no funciona en 10.9. Nunca lo he probado en 10.10 o 10.11.

Edición: Un comentario anterior de @user3439894 señaló que esto realmente no debería funcionar. Una máquina que sirve sobre samba no debería servir nada sobre http.

Pero, es hizo me funciona, y sigue funcionando. Toda mi empresa utiliza este script con bastante frecuencia, y el Mac Mini al que nos conectamos no tiene activado el uso compartido de la web. Pero, sólo he probado este método con ese único servidor mac mini, así que no sé si será universal.

Utilizando ping sería probablemente más robusto que curl Aunque estoy bastante seguro de que primero probé con el ping y no conseguí que funcionara de forma fiable. Sin embargo, no recuerdo exactamente, ya que han pasado un par de años.

Es posible que en las próximas dos semanas vuelva a sumergirme en esto para mis propios fines, y actualizaré esta respuesta si lo hago...

Determinar si una URL es accesible

Esto es algo que es mucho más sencillo de lo que la gente piensa, pero también no suele ser lo primero que se le ocurre a nadie porque este es uno de los pocos usos prácticos de la función de AppleScript URL clase.

Puede tomar una URL de Internet cotidiana como una cadena y coaccionarla para que escriba la clase URL Por ejemplo

"https://duckduckgo.com" as URL

que devuelve el siguiente registro:

{
    class: URL, 
    scheme: secure http URL, 
    path: "https://duckduckgo.com", 
    host: {
        class: Internet address, 
        DNS form: "duckduckgo.com", 
        port: 443, 
        dotted decimal form: "52.213.95.108"
    }
}

(aunque AppleScript no lo imprimirá). Aquí hay una coerción similar usando una dirección web que sé que no existe:

"https://quackquackyo.com" as URL
    --> {
            class: URL, 
            scheme: secure http URL, 
            path: "https://quackquackyo.com", 
            host: {
                class: Internet address, 
                DNS form: "quackquackyo.com", 
                port: 443
            }
        }

Entonces es sólo un juego de detecta la diferencia si una URL se resuelve a una dirección alcanzable, el programa de AppleScript URL devuelve un objeto de clase dotted decimal form que representa la dirección IP del servidor; si la URL no se resuelve, se omite esta dirección IP.

Utilizando este discriminador, podemos crear un manejador que devuelva true o false dependiendo de si una determinada URL es accesible o no:

on urlIsReachable(www as URL)
    local www
    set www to www's host & {dotted decimal form:false}
    return www's dotted decimal form ≠ false
end urlIsReachable

Para usar:

urlIsReachable("https://www.google.com")    --> true
urlIsReachable("https://CK-mac.local")      --> true
urlIsReachable("http://CK.local")           --> true
urlIsReachable("http://CK-maaaaaaac.local") --> false

Tenga en cuenta, sin embargo, que esto no le dice que las máquinas en mi red llamada CK-mac y CK tienen el afp o smb puertos de intercambio de archivos abiertos, y tratando de resolver un afp:// o smb:// arrojará un error, porque el URL El objeto de clase no reconoce muchos esquemas. También significa que si una máquina ha cerrado su http o https (80 y 443, respectivamente), entonces estos devolverán false aunque los puertos 445 ( smb ) o 548 ( afp ) están abiertos. Así que, aunque este método tiene limitaciones, no creo que sea una situación muy común que los puertos de intercambio de archivos estén abiertos en una máquina con los puertos de transferencia de hipertexto específicamente cerrados. El método de AppleScript URL La clase también reconoce ftp:// URLs, pero si se resuelve para cualquiera de sus dispositivos personales, probablemente debería desactivar su ftp servidor para que no lo haga.

Cómo determinar si un disco está montado en Finder

Parece que tienes un método para determinar si un disco está montado o no en tu sistema de archivos, y es uno perfectamente adecuado. Sin embargo, siempre soy consciente de lo temperamental que es Buscador puede ser, y la facilidad con la que se bloquea al hacer otras tareas. Por lo tanto, personalmente, si puedo evitar involucrarlo (en casi todo), lo haré. Y, por supuesto, si puedes aprovechar las capacidades integradas de AppleScript sin llamar a otra aplicación para hacer un trabajo, eso (casi) siempre va a ser más rápido y más fiable. Así que, con este fin, aquí hay un manejador rápido:

on volumeIsMounted(name as text)
    local name
    "/Volumes/" & name as «class furl» as {alias, text}
    return result's class ≠ text
end volumeIsMounted

Para usar:

volumeIsMounted("MEDIA LIBRARY")      --> true
volumeIsMounted("rsaref")             --> true
volumeIsMounted("MEDIAAAAAA LIBRARY") --> false

Como referencia, "MEDIA LIBRARY" es el nombre del disco remoto en mi red conectado a la máquina CK.local que se monta como un afp fileshare con el fin de hacer pruebas. También quería probar un servidor remoto-remota, así que monté un ftp servidor disponible para todos en "ftp://static.zedz.net/pub/security/cryptography/libraries/math/rsaref" (esto no significa que yo respalde la seguridad de abrir cualquier archivo que puedas encontrar en este servidor, así que simplemente sé considerado antes de considerar el acceso a cualquier archivo compartido al azar a través de Internet). "MEDIAAAAAA LIBRARY" Supongo que ya lo sabes, es no montado en mi sistema de archivos.

Esto realmente libera a todo tu script de tener que usar Buscador en absoluto. mount volume es un Adiciones estándar por lo que no es necesario utilizarlo en un Buscador tell y será más eficaz si no lo es. Nada más aquí o en su script requiere Buscador o bien. Eso es una victoria, en mi opinión.