Activar el control por voz sin el icono del micrófono flotante

Dime si esta solución te funciona. En lugar de mover el icono a un lugar diferente, mi solución simplemente lo activa y desactiva con un rápido applescript. Crédito a Jono en el Foro de Keyboard Maestro para resolver esto.

Ventajas del método: ahorra una cantidad ridícula de ram (VC toma toneladas) Desventajas: hay que activarlo y tarda unos segundos.

El siguiente applescript, que puede ser activado por un flujo de trabajo/acceso directo de Automator, activará y desactivará el control por voz. Yo uso Maestro del teclado y Alfred para activarlo yo mismo.

tell application "System Preferences"
    reveal anchor "Dictation" of pane id "com.apple.preference.universalaccess"
    -- activate
end tell

delay 0.5
tell application "System Events"
    tell process "System Preferences"
        click checkbox "Enable Voice Control" of group 1 of window "Accessibility"
    end tell
end tell
tell application "System Preferences" to quit

No es una cura, sino una opción visual: Muevo el icono de 'Control de Voz' un 99% fuera de la pantalla, puedes seleccionar donde quieras moverlo fuera de la pantalla

Otra posible solución para ocultarlo (pero sólo mientras no lo uses)... con Siri activado en tu Mac, simplemente di "Oye Siri, activa el Control por Voz", y "Oye Siri, desactiva el Control por Voz" cuando hayas terminado.

No es la solución perfecta que buscas, pero eliminará la ventana de control mientras no se use. Y si el Control por Voz está ocupando memoria, esto ayudaría. Eso sí, activar Siri si no lo estaba antes podría ocupar memoria extra de todos modos.

El siguiente código AppleScript ocultará la molesta ventana flotante de Dictado mientras se utiliza el Control por Voz.

Después de probar varios escenarios, con versiones anteriores del código AppleScript en mi solución, me encontré con varias situaciones en las que la ventana flotante de Dictado volvía a aparecer. Cuando esto ocurría, era necesario ejecutar de nuevo el código para volver a ocultar la ventana flotante de Dictado. Para evitar tener que ejecutar el código cada vez que aparecía la ventana flotante de Dictado, decidí guardar el AppleScript como una aplicación que permanece abierta con un controlador de inactividad cuya función es volver a ocultar la ventana flotante de Dictado si vuelve a ser visible.

En script Editor.app, guarde este siguiente AppleScript como una aplicación abierta

on idle
    if application "DictationIM" is running then
        hideDictation(true)
    else
        quit
    end if
    return 5 -- In Seconds
end idle

to hideDictation(|true or false|)
    tell application "System Events"
        try
            set value of attribute "AXHidden" of ¬
                application process "Dictation" to |true or false|
        end try
    end tell
end hideDictation

on quit
    --  Executed When The Script Quits
    hideDictation(false)
    continue quit -- Allows The Script To Quit
end quit

Yo guardé la mía como "Invisible Dictation.app". Ya que estás usando el control de voz, también puedes crear un nuevo comando de voz para ejecutar "Invisible Dictation.app" mientras estás en ello. Con el control de voz activado, vaya al Finder y seleccione el nuevo applet "Invisible Dictation.app" y simplemente diga el comando "Make This Speakable" y cuando se abra su ventana de configuración, asígnele un valor "When I say" y guarde su nuevo comando de dictado.

Hay algunos inconvenientes menores que he notado cuando se ejecuta este applet AppleScript que permanece abierto.

1. También oculta algunas ventanas emergentes o de diálogo cuando se hacen visibles. Por ejemplo, si utiliza el comando de voz "Mostrar comandos", mientras su applet se está ejecutando, la ventana de comandos aparecerá brevemente y luego se oculta junto con la ventana de Dictado. Por eso he añadido un return 5 al código. Da unos segundos para ver cualquier ventana emergente o de diálogo cuando se hacen visibles antes de que se oculten por el applet en ejecución. PERO si sale del "Invisible Dictation.app" en ejecución, después de ver cualquier ventana emergente o de diálogo que haya desaparecido repentinamente, volverán a ser visibles.
2. Si intenta utilizar los comandos de voz "Mostrar números" o "Mostrar la cuadrícula de la ventana" mientras el applet se está ejecutando, los números y/o la cuadrícula también se ocultarán.

Es una obra de arte muy bonita, pero estorba, sobre todo a los discapacitados visuales, que son los que más necesitan esta tecnología de asistencia. ¡Qué manera de diseñar una función, Apple! ¿Puedo conseguirlo en azul aciano? Por cierto, estaría bien en la barra de menús.