¿Cómo grabar en pantalla usando AppleScript en Catalina?

Sin ver a su AppleScript código, todo lo que puedo decir es que para mí, como un ejemplo, en macOS Alta de la Sierra de hacer una grabación de la pantalla requiere de codificación diferentes, a continuación, en macOS Catalina, ya que éste no utiliza el Reproductor QuickTime para que haga la grabación de la pantalla.

Esto también puede ser cierto para macOS Mojave, sin embargo, el siguiente ejemplo de AppleScript código fue probado bajo macOS Catalina:

--  # Setup to do a screen recording.

tell application "QuickTime Player" to new screen recording

--  # Start the screen recording.

tell application "System Events" to tell process "Screen Shot"
    repeat until exists button "Record" of its front window
        delay 0.1
    end repeat
    click button "Record" of its front window
end tell

--  # Set the time in seconds you want the recording to be.

delay 2

--  # Stop the recording.

tell application "System Events" to ¬
    click menu bar item 1 ¬
        of menu bar 1 ¬
        of application process "screencaptureui"

En este punto, por defecto, cuando la pantalla de grabación se detiene, se guarda en el Escritorio , como por ejemplo, la Grabación de la Pantalla 2019-11-01 en 3.38.00 PM.mov en mi sistema y se abre en el Reproductor QuickTime.

Una codificación adicional se puede incluir a hacer cualquier otra cosa que uno quisiera hacer con la grabación de la pantalla (dentro de los límites de la aplicación de destino y AppleScript).

Que todo lo dicho, desde macOS Catalina en realidad está utilizando una aplicación diferente para que haga la grabación de la pantalla y no QuickTime Player, uno podría omitir el uso de QuickTime Player y crear la grabación de la pantalla mediante el siguiente ejemplo AppleScript código, que utiliza el sistema por defecto de método abreviado de teclado ⇧⌘5:

--  # Setup to do a screen recording.

tell application "System Events" to keystroke "%" using {shift down, command down}

--  # Start the screen recording.

tell application "System Events" to tell process "Screen Shot"
    repeat until exists its front window
        delay 0.1
    end repeat
    if not (exists button "Record" of its front window) then
        click checkbox "Record Entire Screen" of its front window
    end if
    click button "Record" of its front window
end tell

--  # Set the time in seconds you want the recording to be.

delay 2

--  # Stop the recording.

tell application "System Events" to ¬
    click menu bar item 1 ¬
        of menu bar 1 ¬
        of application process "screencaptureui"

• Nota el uso de % en lugar de 5 en keystroke "%" como el cambio de tecla es presionada y estoy en un inglés de EE.UU. teclado.
• Las habituales advertencias, respecto a Preferencias del Sistema > Seguridad y Privacidad > Privacidad, aplicar.

_{Nota: El ejemplo de AppleScript código es sólo eso y no contiene, además, errores de manejo, según sea apropiado. La responsabilidad recae sobre el usuario para agregar cualquier error de manipulación como puede ser apropiado, necesitaba o quería. Echa un vistazo al tratar de instrucción y de error de instrucción en la Guía de Lenguaje de AppleScript. Véase también el Trabajo con los Errores.}