Cómo hacer que mi traductor binario procese varios números binarios

Tu script puede ser muy simplificado. Lo que parece que estás haciendo es convertir un número binario en base 10 (denario), y de ahí a un código de caracteres. (Nota al margen: Siempre es útil tratar de ser explícito al describir lo que tu código hace--o pretende hacer).

set bits to every character in the text returned of ¬
    (display dialog "Binary Input:" with icon note ¬
    buttons {"Cancel", "Convert"} default button 2 ¬
    with title "Binary to Text Conversion")

set |2ⁿ| to 1 -- powers of 2, i.e. 2⁰, 2¹, 2², 2³,..., 2⁷
set d to 0    -- the base 10 value (replaces your decimalString)

repeat with bit in the reverse of the bits
    set d to d + bit * |2ⁿ|
    set |2ⁿ| to 2 * |2ⁿ|
end repeat

set char to character id d
return char

Se desea repetir este proceso varias veces para convertir tantos números binarios como el usuario suministre. No hay muchas opciones para permitir fácilmente obtener múltiples valores de un usuario. Pero parece que usted está experimentando con la codificación binaria/texto de los datos, y que estos números binarios probablemente representan 8 bits de un solo byte de datos, por lo tanto parece razonable dejar que un usuario suministre tantos bytes de datos que desee en un solo diálogo de entrada, simplemente separando cada valor binario por un espacio, por ejemplo

"1011010 11010011 01011000 ..."

que representaría tres bytes de datos en forma binaria que son fáciles de dividir en elementos individuales y convertir uno por uno.

Para ello, tiene sentido poner el trozo de código que hace la conversión base dentro de un handler (función) que puede reutilizarse una y otra vez para realizar tantas conversiones como se necesite sin tener que escribir una y otra vez un código idéntico.

Aquí hay un borrador de un script que hace todo esto:

set bytes to every word in the text returned of ¬
    (display dialog "Binary Input:" with icon note ¬
    buttons {"Cancel", "Convert"} default button 2 ¬
    with title "Binary to Text Conversion")

set chars to {} -- this will fill with each decimal conversion

repeat with bits in bytes
     -- call the handler below
    set end of chars to the decimal from bits
end repeat

-- Now convert the decimal numbers to text
return character id chars

# A handler that takes a binary number and returns its decimal
# representation.  The binary value can be passed in any of the
# following ways:
#        1. a list of characters of numbers
#             e.g. {0, 1, 0, 1, 1, 0, 1, 0}, or
#                  {"0", "1", "0", "1", "1", "0", "1", "0"}  
#        2. a string, e.g. "01011010"
#        3. a number, e.g. 1011010
to decimal from binary as {list, text, integer}
    local binary

    set |2ⁿ| to 1
    set d to 0

    tell a reference to binary to if its class ≠ list then ¬
        set the contents to the characters of (it as text)

    repeat with bit in the reverse of the binary
        set d to d + bit * |2ⁿ|
        set |2ⁿ| to 2 * |2ⁿ|
    end repeat

    return d
end decimal