AppleScript no puede obtener una fecha como cadena

Puede que no sea una solución directa o la respuesta que está buscando, pero el siguiente código AppleScript proporciona ejemplos de cómo convertir una cadena de fecha corta dada en una fecha real, cómo extraer los elementos de la fecha, editar y establecer la fecha y valores de tiempo, y para crear su propia fecha y hora personalizadas como una cadena. Espero que esto ayude.

 set dateAsText to "9/23/16"

-- converts dateAsText into an actual date
set someDate to date dateAsText -- date "Friday, September 23, 2016 at 12:00 AM"

-- extract the short date from someDate... as a string
set shortDate to short date string of someDate -- "09/23/16"

-- change the time value of someDate from "12:00 AM" to "5:00 PM"
set adjustedDate to date "5:00 PM" of someDate -- date "Friday, September 23, 2016 at 5:00 PM"


-- extract elements from adjustedDate... as strings
set theTime to time string of adjustedDate -- "5:00 PM"

set theWeekday to weekday of adjustedDate -- Friday
set theWeekday to (weekday of adjustedDate) as string -- "Friday"

set theDay to day of adjustedDate -- 23
set theDay to (day of adjustedDate) as string -- "23"

set theMonth to month of adjustedDate -- September
set theMonth to (month of adjustedDate) as string -- "September"

-- edit values of adjustedDate
set day of adjustedDate to 14 -- date "Wednesday, September 14, 2016 at 5:00 PM"
set year of adjustedDate to 1978 -- date "Thursday, September 14, 1978 at 5:00 PM"

------------
set customDate to short date string of adjustedDate & space & theTime -- "09/14/78 5:00 PM"
 

Parece string value (no value) es el término que estás buscando. Excel almacena las células en su formato raw (p. ej., fecha, número, etc.) pero, a continuación, se ha separado la capacidad de dar formato a los valores. Así, por ejemplo, se puede almacenar el número 2.33423 , pero la pantalla como 2.3 , mostrando sólo un decimal.

En Applescript, esta es la diferencia entre el término value (que es el valor bruto de la forma en que Excel guardado) y string value que es la forma en que Excel muestra de ello.

tell application "Microsoft Excel"
    get value of active cell
    -- date "Sunday, May 19, 2019 at 12:00:00 AM"

    get string value of active cell
    -- "5/19/19"
end tell

Ahora, siempre que ya han fijado el objetivo de formato en la celda, puede establecer el contenido de la celda, simplemente, por algo como esto:

tell application "Microsoft Excel"
    set value of active cell to "6/18/2019"
end tell

Siempre esta celda con formato de una fecha, que se interpreta como tal.

Volviendo al problema original en la mano, usted puede revisar AppleScript las definiciones de clase de la clase date -- desplácese hacia abajo hasta encontrar la descripción de todo. La razón por la que month aparece de manera diferente, es que es una constante no es un entero. La fecha es un tipo de clase en el interior de AppleScript, que tiene propiedades asociadas usted puede obtener o manipular.

Por ejemplo: Uno podría llegar el mes como un número entero de la siguiente manera (de lo contrario, será una constante).

tell application "Microsoft Excel"
    set theDate to value of active cell as date
    get (month of theDate) as integer
end tell

Referencias adicionales:

• Excelente discusión sobre AppleScript tiempo y formato de fecha.
• Adicional código de ejemplo en la configuración de la fecha en una celda de Excel. No estoy seguro de que esto es necesario, pero le muestra cómo usted puede hacerlo.

Tome la fecha que Excel le está dando actualmente y vuelva a aplicar el formato que necesita para poner en Filemaker de esta manera:

     tell theDate to set dateList to {its month as integer as text, day as text, year as text}
set {saveTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, {"/"}}
set newDate to dateList as string
set AppleScript's text item delimiters to saveTID