Un servicio de automatización que abre un archivo con el mismo nombre pero diferente extensión del elemento seleccionado

No quieres cambiar el nombre de el archivo, sólo tiene que utilizar una nueva ruta de carpeta para buscar un archivo que coincida. Automator no incluye acciones por defecto para este tipo de cosas, por lo que tendrás que usar una acción de terceros o un script, o hacer esa parte tú mismo.

Para una solución AppleScript, cree un nuevo flujo de trabajo de servicio/acción rápida que reciba files or folders en el Finder y añadir un Ejecutar AppleScript reemplazando la acción por defecto script por lo siguiente:

on run {input, parameters} -- match name of an input item to a videoFolder item
    set videoFolder to ((path to home folder) as text) & "Movies:Videos:" -- the HFS folder path containing matching video files
    repeat with anItem in the input -- return the first match
        set {theName, theExtension} to getNamePieces from anItem
        tell application "Finder"
            set matches to (files of folder videoFolder whose name starts with theName) -- match any extension
            if matches is not {} then return (first item of matches) as alias
        end tell
    end repeat
    return missing value -- no match
end run

to getNamePieces from someItem -- get name and extension from a file item
    tell application "System Events" to tell disk item (someItem as text)
        set {theName, theExtension} to {name, name extension}
    end tell
    if theExtension is not "" then
        set theName to text 1 thru -((count theExtension) + 2) of theName -- the name part
        set theExtension to "." & theExtension
    end if
    return {theName, theExtension}
end getNamePieces

...y luego terminar añadiendo un Abrir elementos del buscador y guardar el flujo de trabajo.