Quiero eliminar el proceso de la aplicación Automator, pero no puedo encontrar el nombre en el monitor de actividad.
Respuestas
¿Demasiados anuncios?
wch1zpink
Puntos
11
Escribí un AppleScript hace un tiempo que me ayudó a abordar el mismo tipo de problema que está tratando con. En resumen, el código da las opciones para elegir ya sea visible o invisible de los procesos de solicitud, en la que desea asesinados. A continuación, el código utiliza la secuencia de comandos de shell de comandos kill para terminar en aquellos procesos que por su IDENTIFICADOR de proceso.
La ventaja de usar este en lugar de un Monitor de Actividad, es que este código permite la selección de varios elementos o procesos para matar de un solo tiro. Monitor de actividad sólo permite la selección de un proceso al mismo tiempo.
Con su circunstancia, me gustaría ejecutar este código y elija primero para ver la lista de visibilidad de aplicaciones. Si Automator no está en la lista, yo elegiría a matar Buscador en esa lista (que va a matar Buscador y relanzar). A continuación, comprobar para ver si eso resuelve el problema. Si no, a continuación, ejecute la secuencia de comandos de nuevo y seleccione para ver la lista de los invisibles, de los procesos de solicitud, seleccionando "WorkflowServiceRunner" (si es que existe), el Sistema de "Eventos", y "interfaz de usuario del Sistema del Servidor" y matar a todos los procesos (que debe matar a ellos y relanzar ellos también)
Puede ejecutar el siguiente código directamente en el Editor de secuencias de Comandos.aplicación o guardar el código en el Editor de secuencias de Comandos.la aplicación como una aplicación y al igual que cualquier otra aplicación en el Finder, haga doble clic en el archivo para ejecutarlo.
use framework "Foundation"
use scripting additions
property appsToKill : missing value
property NSArray : a reference to current application's NSArray
activate
set theChoice to button returned of (display dialog ¬
"WOULD YOU LIKE TO LIST VISIBLE OR INVISIBLE APP PROCESSES?" buttons ¬
{"CANCEL", "VISIBLE", "INVISIBLE"} default button ¬
"INVISIBLE" cancel button "CANCEL" with title ¬
" WOULD YOU LIKE TO LIST VISIBLE OR INVISIBLE APP PROCESSES? " with icon ¬
2 giving up after 10)
if theChoice is "INVISIBLE" then
listInvisibleAppProcesses(false)
else if theChoice is "VISIBLE" then
listInvisibleAppProcesses(true)
else if theChoice is "CANCEL" then
return
else if theChoice is "" then
return
end if
set aList to ((NSArray's arrayWithArray:appsToKill)'s ¬
sortedArrayUsingSelector:"caseInsensitiveCompare:") as list
activate
set killApp to (choose from list ¬
aList with title "Choose The App To Kill" with prompt ¬
"Choose The App" OK button name "OK" cancel button name ¬
"CANCEL" with multiple selections allowed)
set pidList to {}
if killApp is not false then
tell application "System Events"
repeat with i from 1 to count of killApp
set thisItem to item i of killApp
tell application process thisItem
set thePID to unix id
set end of pidList to thePID
end tell
end repeat
end tell
else
return
end if
set text item delimiters to space
do shell script ({"kill", pidList} as text)
on listInvisibleAppProcesses(trueOrFalse)
tell application "System Events"
set appsToKill to name of every application process ¬
where visible is trueOrFalse
end tell
end listInvisibleAppProcesses
Esperemos que esto le ayudará con su situación, pero si no es así, el ahorro de este código como una aplicación en el Editor de secuencias de Comandos.la aplicación y el uso de ella en lugar de un Monitor de Actividad... Para matar aplicaciones... Debe demostrar ser una útil herramienta en tu arsenal.
