Números: ¿menú o lista para saltar a una hoja específica?

¿Existe alguna forma de acceder a un menú o lista de todas las hojas de un documento de Numbers, de modo que pueda saltar rápidamente a una hoja específica sin tener que desplazarme o paginar una por una con los atajos de teclado anterior/siguiente?

La única forma que conozco es AppleScript y utilizar algún mecanismo para activar el script Por ejemplo, un Automatizador Servicio 1 .

Por ejemplo, pulsando S en Números con un Acciones.números documento abierto y frontalmente, obtengo un choose from list cuadro de diálogo como se muestra en la siguiente imagen:

A continuación, seleccioné hoja Historial de 1 año y luego hizo clic en OK y fue llevado a ese hoja en el documento. Tenga en cuenta que Haciendo doble clic en en cualquier elemento de la lista lo lleva a uno a eso hoja directamente sin tener que hacer clic en OK o pulse Entre en . (También puede escribir el primer carácter del elemento de la lista o utilizar también las teclas de flecha abajo/arriba).

Obviamente con un Números que sólo tiene cinco hojas esto no es realmente necesario, y es sólo un ejemplo para cuando el documento tiene el número de hojas que necesitaría desplazarse a través de las pestañas de las hojas en el documento para llegar a la deseada. En mi pantalla Retina del MBP 15" pude ver 37 hojas sin tener que desplazarme en el Ir a la hoja... de la lista. (Esto variará según la resolución de la pantalla y la altura del Dock).

Crear un Automatizador Servicio 1 como se muestra en la siguiente imagen:

Ejemplo AppleScript código :

tell application "Numbers" to set sheetList to name of every sheet of document 1

tell current application to activate
choose from list sheetList with title "Go To Sheet..." with prompt "Please select a sheet name:"
if the result is not false then
    my selectSheet(result as text)
end if

on selectSheet(n)
    try
        tell application "Numbers"
            activate
            -- # The following code causes Numbers to go to the selected sheet.
            -- # It is not modifying the existing data in the target cell, however,
            -- # it does cause a saved document to show as edited, temporarily, 
            -- # and resolved by the code in the following System Events tell block.
            set value of first cell of first table of sheet n of front document to ¬
                (value of first cell of first table of sheet n of front document)
        end tell

        tell application "System Events"
            -- # Undo Typing so the document doesn't show as edited if already saved,
            -- # and if already saved the modified date/time stamp shouldn't change.
            keystroke "z" using command down
            -- # Press the escape key to remove focus from cell A1.         
            key code 53
        end tell

    on error eStr number eNum
        display dialog eStr & " number " & eNum buttons {"OK"} ¬
            default button 1 with icon caution
        return
    end try
end selectSheet

_{<strong>Nota sobre el código AppleScript: </strong>Hasta donde yo sé, <strong>Números </strong>no tiene un <strong>AppleScript </strong><em>comando </em>para seleccionar un determinado <em>hoja </em>y esto es una especie de método alternativo y hace que un documento guardado aparezca como editado temporalmente, aunque no esté alterando el <em>valor </em>de la <em>célula objetivo </em>y resuelto por el código en el bloque System Events tell. Funciona estableciendo el <em>valor </em>de <code>cell "A1"</code> a su <em>valor actual </em>Así que, aunque se percibe como una edición, no <em>datos </em>ha sido alterado desde su <em>valor actual </em>y si ya se ha guardado, la marca de fecha/hora de modificación no debería cambiar. Esto me funciona en <strong>Números </strong>5,1 en <strong>MacOS High Sierra </strong>en un <em>lectura-escritura </em>documento, y es la razón por la que lo utilizo. Tal y como está codificado, no está pensado para ser utilizado en un <em>bloqueado </em>o <em>Sólo lectura </em>documento. En este caso, sería necesaria una codificación adicional.}

Para Preferencias del sistema > Teclado > Atajos > Servicios :

Nota: A veces con un Automatizador Servicio 1 y la asignación de un atajo de teclado es posible que primero tenga que activarlo desde la aplicación de destino Servicios menú una vez. A partir de ese momento el atajo de teclado debería funcionar normalmente.

_{¹En <strong>MacOS Mojave </strong>un <strong>Automatizador </strong><em>Servicio </em>se llama <em>Acción rápida </em>.}

Nota: El ejemplo AppleScript código es sólo eso y sin la inclusión de tratamiento de errores no contiene ningún otro tratamiento de errores según corresponda. Corresponde al usuario añadir cualquier tratamiento de errores como sea apropiado, necesario o deseado. Eche un vistazo a la intente declaración y error declaración en el Guía del lenguaje AppleScript . Véase también, Trabajar con errores .