¿Cómo puedo activar el cambio automático de gráficos mediante el terminal?

He buscado en Google y no conozco ninguna utilidad nativa de línea de comandos o un tercero utilidad de línea de comandos que puede conmutar el estado del cambio automático de gráficos; sin embargo, se puede hacer desde el línea de comandos utilizando AppleScript para alternar el [] Conmutación automática de gráficos casilla de verificación en el Ahorro de energía panel en Preferencias del sistema .

En lugar de encontrar un utilidad nativa de línea de comandos o un tercero utilidad de línea de comandos o hasta que se publique una respuesta mejor, lo siguiente le permitirá alternarlo desde el línea de comandos en, por ejemplo Terminal .

1. En Terminal utilice lo siguiente comando compuesto para crear el archivo y abrirlo:

   touch togags; open togags

2. Copiar y pegar el ejemplo AppleScript código que se muestra más abajo, en el togags archivo .

3. Guarde y cierre el archivo .

4. Haga que el archivo ejecutable :

   chmod u+x togags

Utilicé togags para: [tog]gle [a]utomatic [g]raphics [s]witching

Ahora puede utilizarlo desde el directorio es en el uso de ./togags De lo contrario, /path/to/togags sin embargo, es mejor que lo coloques en un directorio que está dentro de su PATH declaración . Luego se puede utilizar desde cualquier lugar con sólo togags (o lo que sea que haya nombrado el ejecutable ).

NOTA: Esto también requerirá dar Terminal privilegios de accesibilidad para que esto funcione correctamente.

La ejecución de la comando dos veces, para mostrar su salida:

$ togags
   Automatic Graphics Switching is: OFF
$ togags
   Automatic Graphics Switching is: ON
$ 

Lo siguiente ejemplo AppleScript código fue probado y me funciona tal y como está codificado en MacOS High Sierra . Un cambio menor puede ser necesario para MacOS Mojave Sin embargo, no puedo probarlo en este momento. Lo mismo ocurre con las versiones más antiguas de OS X/MacOS.

Ejemplo AppleScript código :

#!/usr/bin/osascript

if running of application "System Preferences" then
    try
        quit application "System Preferences"
    on error
        do shell script "killall 'System Preferences'"
    end try
end if

repeat while running of application "System Preferences" is true
    delay 0.1
end repeat

tell application "System Preferences"
    reveal pane id "com.apple.preference.energysaver"
    repeat until exists window "Energy Saver"
        delay 0.1
    end repeat
end tell

tell application "System Events" to tell ¬ 
    group 1 of window "Energy Saver" of application process "System Preferences"
    repeat until exists checkbox "Automatic graphics switching"
        delay 0.1
    end repeat
    click checkbox "Automatic graphics switching"
    set cbAGS to (value of checkbox "Automatic graphics switching") as boolean
end tell

quit application "System Preferences"

if cbAGS then
    return "   Automatic Graphics Switching is: ON"
else
    return "   Automatic Graphics Switching is: OFF"
end if

Nota: El ejemplo AppleScript código es sólo eso y, aparte de lo que ya está codificado, no contiene ninguna gestión de errores adicional que pueda ser apropiada. Es responsabilidad del usuario añadir cualquier gestión de errores que sea apropiada, necesaria o deseada. Eche un vistazo al pruebe con declaración y error declaración en el Guía del lenguaje AppleScript . Véase también, Trabajar con errores .