Modificación de las salidas de sonido con Applescript (parece que he extraviado mi grupo de pestañas)

Mientras que la otra respuesta de hecho funciona para mí en mi sistema que ejecuta MacOS High Sierra sin embargo, tengo que publicar una respuesta principio KISS.

Basta con añadir lo siguiente código a su actual código :

repeat until exists tab group 1 of window "Sound"
    delay 0.1
end repeat

Así que su código ahora se verá así:

tell application "System Preferences"
    reveal anchor "output" of pane id "com.apple.preference.sound"
end tell

tell application "System Events" to tell process "System Preferences"
    repeat until exists tab group 1 of window "Sound"
        delay 0.1
    end repeat
    tell table 1 of scroll area 1 of tab group 1 of window 1
        select (row 1 where value of text field 1 is "Andrea Comm USB-SA Headset")
    end tell
end tell

quit application "System Preferences"

Definitivamente hay un nivel de sofisticación en la otra respuesta; sin embargo, me imagino que puede ser un poco difícil de entender para aquellos que son nuevos en AppleScript y por qué un El principio KISS respuesta se está proporcionando.

He probado tu script en mi sistema ( Información del sistema: Versión de AppleScript: 2.7 Versión del sistema: 10.13.6), y ha funcionado perfectamente. Mi único pensamiento es un eco de la sugerencia de @tetsujin sobre la construcción de suficientes controles para asegurar que los elementos de la interfaz de usuario existe antes de tratar de hacer las cosas con ellos.

Puede ser que su sistema esté tardando más en cargar el Preferencias del sistema y su contenido y, por lo tanto, el script procede a ejecutar las siguientes líneas de código de forma prematura, lo que da lugar a un "can't get tab group 1" error.

Sin embargo, esto no explica satisfactoriamente por qué esto sucede en ejecuciones alternas de su script, lo cual suena muy extraño.

Volví a redactar tu script y utilicé mi formato personal y estandarizado que uso con todos estos Preferencia del sistema UI AppleScripts. Ha incorporado comprobaciones para evitar que el script continúe a menos que se confirme la existencia del elemento de interfaz de usuario en cuestión (deja de esperar después de un breve período y termina el scriptque regresa false mientras que cualquier ejecución exitosa del script devuelve true ).

use Prefs : application "System Preferences"
use sys : application "System Events"

property pane : a reference to pane id "com.apple.preference.sound"
property anchor : a reference to anchor "output" of my pane

property process : a reference to application process "System Preferences"
property window : a reference to window "Sound" of my process
property tab group : a reference to tab group 1 of my window
property scroll area : a reference to scroll area 1 of my tab group
property table : a reference to table 1 of my scroll area
property row : a reference to row 1 in my table

property Headphones : a reference to (my row where the value of ¬
    text field 1 = "Headphones")
property Headset : a reference to (my row where the value of ¬
    text field 1 contains "Andrea Comm")

on zzz(x, || as boolean)
    local x, ||

    repeat 20 times -- 20 x 0.2s = 4s max. wait
        if || = (x exists) then return true
        delay 0.2
    end repeat

    false
end zzz

on quit e as boolean
    continue quit Prefs
    return e
end quit

-- quit 1
-- if zzz(my process, no) = false then return quit 0

reveal my anchor
if zzz(my row, yes) = false then return quit 0

select Headset --OR: Headphones
-- quit 1

Hay tres líneas comentadas, que he numerado. Estas pueden permanecer comentadas durante la prueba del script, lo que asegurará la Preferencias del sistema permanece visible (una vez que la has puesto en primer plano manualmente), para que puedas ver físicamente si el dispositivo de salida está siendo seleccionado o no. Si el script parece ejecutarse correctamente, puedes eliminar las marcas de comentario y volver a poner en juego esas tres líneas, lo que permitirá Preferencias del sistema para permanecer oculto, fuera de la vista durante una ejecución normal del script, saliendo Preferencias del sistema al final.

En la penúltima línea se editará el nombre del dispositivo a seleccionar, ya sea Headphones o Headset (sin comillas), ambas declaradas como propiedades al inicio del script y que ya albergan las referencias apropiadas al elemento UI de su respectivo dispositivo.