Tomar la captura de pantalla de la pantalla con AppleScript

Como con cualquier script que intenta controlar la interfaz de usuario, este script es frágil y depende de la suficiente retrasos para dar el Vistazo Rápido de la ventana de tiempo para la forma y la imagen para ser pintadas. Aunque el script comprueba la ventana de la existencia, no puede comprobar para asegurarse de que el contenido de la ventana ha sido pintado, así que he tenido resultados variables en las pruebas, incluyendo algunos buenos éxitos:

tell application "Finder"
    if selection = {} then return
    try
        make new folder with properties {name:"Infinity"}
    end try
    set sourcefile to duplicate item 1 of (get selection) to folder "Infinity"
    select the sourcefile
    activate
end tell

repeat with i from 1 to 50
    tell application "System Events"
        keystroke space
        set _W to (a reference to window "Quick Look" of process "Finder")
        repeat until _W exists
            delay 0.5
        end repeat

        delay 1 -- Give time for window to paint

        set [x, y] to _W's position
        set [w, h] to _W's size

        set my text item delimiters to ","
        set R to {x, y, w, h} as text
    end tell

    set my text item delimiters to {".", ":"}
    set filename to "screen shot " & ((current date) as «class isot» as string) & ".jpg"
    set filename to text items of filename as text

    do shell script "screencapture -R " & R & " -t jpg ~/Desktop/Infinity/" & ¬
        (quoted form of the filename)

    tell application "System Events"
        keystroke space
        repeat until not (_W exists)
            delay 0.5
        end repeat
    end tell

    tell application "Finder" to select file filename in folder "Infinity"
end repeat

Debe garantizar la necesaria accesibilidad de los privilegios concedidos por esta secuencia de comandos para ejecutar.

^{Nota: Esta secuencia de comandos se ha escrito y probado usando AppleScript versión: 2.7 Sistema de versión: 10.13.6}