Recrear de edad alias en grandes cantidades para reducir su tamaño de archivo, manteniendo su nombre y la fecha de creación

En macOS 10.14 Mojave, la inspección de cualquier individuo legado alias con Get Info (⌘I) las causas que se regenera con un tamaño más pequeño.

El uso de Obtener Información para regenerar alias a granel, primero muestra una lista de los alias para la actualización en el Finder en la Vista de Lista. Para encontrar todos sus alias, pulse ⌥⌘Espacio para abrir una nueva búsqueda en el Finder, haga clic en '+' para añadir un criterio, y establecer el criterio de "Tipo" es "Otros", escribe en "Alias".

En esta lista de los alias en el Finder, seleccione el primer resultado, a continuación, pulse ⌥⌘I a Mostrar Inspector. El alias seleccionado será regenerado – verá su tamaño de ir hacia abajo. Ahora mantenga pulsada la ↓ de la tecla de flecha para seleccionar cada uno de los alias de una en una. Cada uno de ellos será regenerado, recibiendo una actualización de la Fecha de Modificación, pero manteniendo su Fecha de creación.

Usted tiene que examinar cada uno de los alias de una en una, porque la inspección de varios alias sólo se actualizará la primera.

Aquí es una solución eficiente uso de AppleScript. En El Editor De Secuencias De Comandos.app/Preferencias, seleccione la opción "Mostrar Menú de secuencia de Comandos En la Barra de Menús" Y "Mostrar Ordenador de secuencias de comandos"

A continuación, pegar el siguiente AppleScript código en un nuevo editor de secuencias de comandos documento. Luego guardar ese nuevo AppleScript documento .scpt archivo en la siguiente ubicación...

/Usuarios/TU NOMBRE/Biblioteca/Scripts/

Básicamente este AppleScript código tendrá el alias seleccionado los archivos en el frente de su ventana del Finder y crear nuevos archivos de alias para la ubicación de su elección. Si esto guardar la ubicación es distinta de la ubicación actual de su archivos de alias, se le dará la opción de eliminar los alias original de los archivos. Este código se mantendrá la fecha de creación de los archivos originales, sin embargo, la modificación de la fecha será la fecha en la que los archivos de alias fueron creados.

tell application "Finder" to set oldAliasFileList to selection as alias list

set theOriginalFiles to {}

repeat with oldAliasFile in oldAliasFileList
    try
        tell application "Finder" to set end of theOriginalFiles to ¬
            (original item of oldAliasFile) as alias
    on error errMsg number errNum
        display dialog "Some Item In Your Finder Selection Is Not An Alias File
 Or Its Original Item Cannot Be Found" buttons {"Cancel", "OK"} default button "OK"
        return
    end try
end repeat

activate
set theFolderChoice to display dialog ¬
    "Choose A Destination Folder For Your New Alias Files" buttons ¬
    {"Cancel", "OK"} default button "OK"

if button returned of theFolderChoice is "OK" then
    activate
    set aliasFileDestinationFolder to (choose folder)
else
    return
end if

repeat with thisFile in theOriginalFiles
    tell application "Finder"
        set {creationDate, modificationDate} to {creation date, modification date} of thisFile
        set aNewAliasFile to make new alias file ¬
            at aliasFileDestinationFolder to thisFile ¬
            with properties {creation date:creationDate, modification date:modificationDate}
    end tell
end repeat

activate
set deleteOldAliasFiles to display dialog ¬
    "Would You Like To Delete The Old Alias Files?" buttons ¬
    {"Cancel", "DELETE"} default button "DELETE"

if button returned of deleteOldAliasFiles is "DELETE" then
    tell application "Finder" to delete oldAliasFileList
end if