Secuencia de comandos que crea un buzón (carpeta) con base en el asunto del correo

Yo era capaz de conseguir la ayuda de la oficial de Apple en los Debates del foro, gracias a Barney15-E. he Aquí la respuesta:

Con el fin de desencadenar con un acceso directo, usted necesita para crear un Automator Acción Rápida. Dentro de que la Acción Rápida puede ejecutar este script:

tell application "Mail"
    set selectedMessages to selection
    set mailboxName to subject of item 1 of selectedMessages
    set messageAccount to account of (mailbox of item 1 of selectedMessages)
    set newMailbox to make new mailbox at (end of mailboxes of messageAccount) with properties {name:mailboxName}
    repeat with eachMessage in selectedMessages
        set mailbox of eachMessage to newMailbox
    end repeat
end tell

Para crear la Acción Rápida de abrir Automator. Seleccione la Acción Rápida del tipo de documento de selección. Establecer la Acción Rápida de No aceptar ninguna Entrada en el Correo. Establecer la Imagen y el Color que desee. Arrastre un "Ejecutar AppleScript" acción en el área de flujo de trabajo. Reemplazar todo lo que entre en ejecución/fin de ejecutar las instrucciones con la secuencia de comandos anterior. Guardar la Acción Rápida con un nombre adecuado.

Para dar a la Acción Rápida de un acceso directo, abrir el Teclado de Preferencias del Sistema. Haga clic en la pestaña accesos directos. Seleccione Servicios de la lista. Encontrar su Rápida Acción (probablemente en General). Agregar el acceso directo deseado.

Si desea presentar cada mensaje seleccionado en su propia carpeta, utilice este script en su lugar:

tell application "Mail"
    set selectedMessages to selection
    repeat with eachMessage in selectedMessages
        set mailboxName to subject of eachMessage
        set messageAccount to account of (mailbox of eachMessage)
        set newMailbox to make new mailbox at (end of mailboxes of messageAccount) with properties {name:mailboxName}
        set mailbox of eachMessage to newMailbox
    end repeat
end tell

Si quieres una versión que comprueba la existencia de al menos un mensaje seleccionado, utilice esto:

tell application "Mail"
    set selectedMessages to selection
    if selectedMessages is not {} then
        set mailboxName to subject of item 1 of selectedMessages
        set messageAccount to account of (mailbox of item 1 of selectedMessages)
        set newMailbox to make new mailbox at (end of mailboxes of messageAccount) with properties {name:mailboxName}
        repeat with eachMessage in selectedMessages
            set mailbox of eachMessage to newMailbox
        end repeat
    else 
        display dialog "You did not select a message."
    end if
end tell