Jugar carpeta con el botón de la derecha con iTunes

En Automator de la aplicación, crear una nueva acción rápida. Seleccione la opción "carpetas" para el elemento de "flujo de trabajo recibe actual" y seleccione Finder app como su elección para que la aplicación se ejecute este servicio.

A continuación, agregue un AppleScript de acción a su flujo de trabajo y la inserción de este siguiente AppleScript código de la nueva acción.

property nameExtensions : {"mp3", "wav", "aiff", "m4a"}
on run {input, parameters}
    set thisFolder to input as string
    set newPlaylist to {}

    tell application "System Events"
        set theseFiles to every file of folder thisFolder
        set folderName to name of folder thisFolder
    end tell

    repeat with i from 1 to the count of theseFiles
        set thisFile to item i of theseFiles
        tell application "System Events"
            if name extension of thisFile is in nameExtensions then
                set thisFile to thisFile as alias
                set end of newPlaylist to thisFile
            end if
        end tell
    end repeat

    tell application "iTunes"
        set newPlaylist1 to make new playlist with properties {name:folderName}
        add newPlaylist to newPlaylist1
        play newPlaylist1
    end tell
end run

Usted puede guardar su Automator archivo y el nombre de algo como "Reproducir en"iTunes"

Ahora todo lo que necesitas hacer es hacer clic derecho sobre cualquier carpeta que contiene sus archivos de audio que desee reproducir en iTunes y seleccione el elemento de menú elemento de "Acción Rápida" / "Reproducir en"iTunes"

Esto creará una nueva lista de reproducción en iTunes con el nombre de la carpeta que contiene sus archivos de audio y empezar a jugar de esa lista inmediatamente.

Si usted no desea que la lista de reproducción a ser permanente y desea quitar los archivos después de escuchar a ellos... suena como un buen proyecto para conseguir sus pies mojados con añadir un código adicional que va a hacer eso para usted.

Como una nota del lado, puede que necesite añadir más formatos de archivo de audio a la primera línea en el archivo AppleScript código.

De todos modos creo que todo esto es un buen punto de partida para usted