Cómo añadir carpetas por lotes a las Acciones de carpeta

El siguiente código AppleScript le pedirá que elija el archivo script que desea adjuntar y, a continuación, le ofrecerá dos opciones distintas para añadir varias carpetas a las que adjuntar ese archivo script.

A mí me funciona con la última versión de macOS Mojave.

property pathToFolderActions : ((path to workflows folder as text) & "Applications:Folder Actions:")

tell application "Finder"
    set resourceName to (choose file with prompt ¬
        "Choose The Script File To Attach")
    set resourceName2 to name of resourceName
    set folderActionScript to (container of resourceName as text) & resourceName as string
    try
        duplicate resourceName to folder pathToFolderActions with replacing
    end try
end tell

activate
set theFolders to (choose folder with prompt ¬
    "Choose Folders" default location (path to desktop) ¬
    invisibles false ¬
    with multiple selections allowed)

activate
set chooseAgain to button returned of (display dialog ¬
    "Would You Like To Choose  Additional Folders?" buttons {"NO", "YES"} ¬
    default button "YES" with title ¬
    "Would You Like To Choose  Additional Folders?" with icon 1)

if chooseAgain is "YES" then
    activate
    set moreFolders to (choose folder with prompt ¬
        "Choose Folders" default location (path to desktop) ¬
        invisibles false ¬
        with multiple selections allowed)
    set theFolders to theFolders & moreFolders
end if

repeat with i from 1 to count of theFolders
    set thisItem to item i of theFolders
    tell application "Finder"
        set nameOfTriggerFolder to name of folder thisItem
        set attachFolderActionTo to (container of thisItem as text) & nameOfTriggerFolder
    end tell

    tell application "Folder Actions Setup"
        activate
        try
            set addedFolderAction to make new folder action with properties {name:nameOfTriggerFolder, path:attachFolderActionTo}
        end try
        try
            delay 0.5
            tell addedFolderAction to make new script with properties {name:resourceName2, path:(pathToFolderActions & resourceName2)}
        end try
        if not folder actions enabled then
            set folder actions enabled to true
        end if
    end tell
end repeat

delay 5
tell application "Folder Actions Setup" to quit