Apple script: No se puede obtener la fecha de "2018-12-12 10:00 AM"

Las fechas de AppleScript son notoriamente exigentes con el formato. Se basan en la configuración de la fecha y la hora de tu sistema, así que incluso si consiguiera que un script funcionara correctamente en mi sistema utilizando un formato de fecha y hora específico, probablemente no funcionaría en tu sistema a menos que tuvieras la misma configuración de MacOS.

Por lo tanto, la mejor manera de tratar con los objetos de fecha de AppleScript es crearlos desde cero utilizando componentes de día, mes, año y hora. De esta forma, funcionan de forma consistente en todos los sistemas, pero, sobre todo, te permiten manipularlos en tu propio script sin errores inesperados.

Añade el siguiente manejador al final de tu script. Le proporcionará los medios para crear un objeto de fecha AppleScript suministrándole el día, el mes y el año, y (opcionalmente) los componentes de hora, minutos y segundos:

to makeASDate given year:y as integer ¬
    , month:m ¬
    , day:d as integer ¬
    , hours:h as integer : 0 ¬
    , minutes:min as integer : 0 ¬
    , seconds:s as integer : 0
    local y, m, d, h, min, s

    tell the (current date) to set ¬
        [ASDate, year, its month, day, time] to ¬
        [it, y, m, d, h * hours + min * minutes + s]

    ASDate
end makeASDate

Para utilizarlo, basta con llamar al manipulador de esta manera:

makeASDate given year:2018, month:January, day:23
    --> date "Tuesday, 23 January 2018 at 00:00:00"

o

makeASDate given year:2018, month:1, day:23, hours:14, minutes:30, seconds:00
    --> date "Tuesday, 23 January 2018 at 14:30:00"

Ahora, su siguiente tarea es extraer los componentes de año, mes y día de sus variables para pasarlos al makeASDate manipulador. La forma más fácil de hacerlo es dividiendo sus variables de fecha/hora en palabras. Por ejemplo, con su fecha y hora de inicio:

set [sy, sm, sd] to words of (sDate of theResult)
    --> {"2018", "12", "12"}

set [sh, smin, AMPM] to words of (sTime of theResult)
    --> {"10", "00", "AM"}
if AMPM = "PM" then set sh to sh + 12

y de manera similar con sus tiempos finales. He ilustrado una prueba rápida con su variable de tiempo para determinar si es o no AM o PM, y he cambiado el valor del componente de la hora en consecuencia (el makeASDate utiliza el reloj de 24 horas). Tendrás que hacer otra prueba con tu variable de fecha para determinar en qué formato está la fecha: dd/mm/yyyy o yyyy-mm-dd que podría ser tan fácil como:

if (sDate of theResult) contains "-" then
    set [sy, sm, sd] to words of (sDate of theResult)
else if (sDate of theResult) contains "/" then
    set [sd, sm, sy] to words of (sDate of theResult)
end if

Lo que dijo @CJK - tratar de cocinar una cadena de fecha es una batalla perdida porque depende de la configuración del usuario, utilice los componentes en su lugar - excepto que su controlador no siempre funciona. Si lo ejecuta en un día con un número mayor que el número de días del mes de la entrada, el resultado será el mes después de el que usted pidió. Por ejemplo, si pide "mes:2 día:15" el 31 de enero, obtendrá el 15 de marzo, no el 15 de febrero. Hay tres factores implicados, ninguno de los cuales parece estar explícitamente documentado:

1. AppleScript date los objetos se almacenan como un punto absoluto en el tiempo, no como un conjunto de componentes. (Bueno, sobre todo absolutos: por razones históricas, son relativos a la zona horaria actual). Los componentes se sintetizan bajo demanda a partir de ese punto en el tiempo utilizando el calendario actual.

2. Fijar un componente, como por ejemplo set month of d to April significa que descompone la fecha en componentes, cambia un componente y luego los vuelve a componer en un punto en el tiempo. No se especifica qué ocurre si uno de los componentes está fuera de rango, pero en la práctica, un día fuera de rango se envolverá en algún mes siguiente. Considere, continuando con el ejemplo, set day of d to 41 . El 41 de abril es, lógicamente, 11 días después del último día de abril, el 30 de abril, por lo que se obtiene el 11 de mayo.

3. Incluso cuando se utiliza la sintaxis del conjunto de patrones set {x, y} to {1, 2} Las asignaciones se hacen de una en una. (La documentación https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_cmds.html#//apple_ref/doc/uid/TP40000983-CH216-SW52 los describe como "simultáneos", ya que set {x, y} to {y, x} de hecho intercambia x y y pero eso no es del todo correcto: lo que realmente ocurre es que primero evalúa todas las expresiones, almacenando los resultados en temporales implícitos, y luego asigna los temporales a las variables de una en una. Todas las evaluaciones ocurren antes de todas las asignaciones, pero el orden no está especificado).

Así que, digamos que ejecutas esto el 31 de enero de 2020:

makeASDate given year:2018, month:2, day:15

Lo que ocurre es que:

1. set ASDate to (current date) . ASDate es el 31 de enero de 2020 a la hora actual.
2. set year of ASDate to 2018 . La fecha del ASD es ahora el 31 de enero de 2018.
3. set month of ASDate to 2 . Los componentes especifican el 31 de febrero de 2018, que no existe, por lo que se envuelve: d es ahora el 3 de marzo de 2018.
4. set day of ASDate to 15 . d es ahora el 15 de marzo de 2018, no el 15 de febrero como pediste.

Hay dos maneras de evitarlo: una es establecer primero el day y month en ese orden a 1 primero, y luego aplicar los parámetros de entrada. La otra es utilizar una fecha fija con un mes y un día de baja numeración, digamos "1/1/1904", en lugar de current date como punto de partida. Un manejador corregido podría tener este aspecto:

to makeASDate given year:y as integer ¬
    , month:m ¬
    , day:d as integer ¬
    , hours:h as integer : 0 ¬
    , minutes:min as integer : 0 ¬
    , seconds:s as integer : 0
    local y, m, d, h, min, s, p

    set p to "1/1/1904"
    tell the (date p) to set ¬
        {ASDate, year, its month, day, time} to ¬
        {it, y, m, d, h * hours + min * minutes + s}

    ASDate
end makeASDate