Lanzamiento Visor de Teclado con un Servicio (Mejorado)

Puede iniciar el Visor de Teclado con un acceso directo mediante el uso de Automator y el OS X funcionalidad de los Servicios.

El Visor de Teclado programa de vida en /System/Library/Input Methods/KeyboardViewer.app (en versiones anteriores a Lion, puede ser a /System/Library/Components/KeyboardViewer.component/Contents/SharedSupport/KeyboardViewerServer.app). Abrir con un atajo de teclado mediante el uso de Automator para crear un simple lanzador de servicio.

1. Abrir Automator y seleccione el Servicio como el tipo de su documento nuevo.
2. Establezca las opciones (en la parte superior del área de flujo de trabajo) para "Servicio recibe ninguna entrada en cualquier aplicación".

3. Agregar el Ejecutar AppleScript de acción a su flujo de trabajo, y reemplazar el texto con las siguientes líneas:

   if application "KeyboardViewer" is running then
       quit application "KeyboardViewer"
   end if
   
   activate application "KeyboardViewer"
   
   -- wait until the window has been closed, then end the KeyboardViewer process
   set numberOfWindows to 1
   repeat until numberOfWindows = 0
       delay 5
       tell application "System Events"
           tell process "KeyboardViewer"
               set numberOfWindows to count windows
           end tell
       end tell
   end repeat
   quit application "KeyboardViewer"
   

4. Guardar con un nombre como "Abrir el Visor de Teclado", a continuación, abra las Preferencias de Teclado para los métodos Abreviados de Teclado de la ficha. Seleccione Servicios en el panel de la izquierda y desplázate hasta la parte inferior, donde se puede ver el nombre de su Servicio en virtud de la Sección General.
5. Asegúrese de que esté activada la casilla para habilitar, a continuación, selecciónelo y haga clic en agregar acceso directo para configurar un atajo de teclado.
6. Después de configurar el atajo de teclado, abra el menú de los Servicios en cualquier aplicación (es decir, Finder > Servicios), a continuación, ciérrelo. Por alguna razón mi llave caliente no funcionaba hasta que me hizo esto.

Un par de notas:

• El script requiere que se compruebe el Permitir el acceso para dispositivos de ayuda en el cuadro de Acceso Universal panel de preferencias.
• Cerrar el Teclado en la ventana Visor de realidad no salir de la aplicación, y como Lri señala, puede ser un poco de un recurso de cerdo, por lo que el repeat bucle comprueba cada 5 segundos si el Visor de Teclado tiene todas las ventanas abiertas, y si no, se cierra el proceso.
• Si usted está ejecutando un pre-sistema operativo Lion, usted puede que necesite reemplazar las instancias de KeyboardViewer con KeyboardViewerServer. Yo no tengo nada de pre-Lion útil para probar esto (si alguien podría informar en los comentarios, eso sería genial.
• Debido a que el script se repite hasta que el Visor de Teclado está cerrado, el Automator engranaje de giro icono aparecerá en la barra de menú hasta que se cierra.

Me alegro de haber encontrado este hilo. Basado en las respuestas anteriores, me hizo una Alfred secuencia de comandos de extensión que alterna el Visor de Teclado.

https://dl.dropbox.com/u/29440342/linkedFiles/Keyboard%20Viewer.alfredextension

Proporciona una alfred palabra clave "kv" que alterna el Visor de Teclado y se apaga, ejecutando el siguiente applescript:

-- adapted from http://apple.stackexchange.com/a/62532
if application "KeyboardViewer" is running then
    quit application "KeyboardViewer"
else
    activate application "KeyboardViewer"
end if

(*
-- adapted from http://apple.stackexchange.com/a/59986
tell application "System Events" to tell process "SystemUIServer"
    tell (menu bar item 1 where description is "text input") of menu bar 1
        click
        click (menu item 1 where title ends with "Keyboard Viewer") of menu 1
    end tell
end tell
*)
-- icon ripped from osx /System/Library/PreferencePanes Keyboard.prefPane/Contents/Resources/Keyboard.icns

Me dejó una implementación alternativa comentado, en caso de experimentar problemas de rendimiento que se pretende evitar.

Los Scripts Extra Plugin de Quicksilver ofrece esta funcionalidad, proporcionando Mostrar Visor de Teclado.scpt.

Además, al crear un Quicksilver Gatillo para Mostrar Visor de Teclado.scpt con la acción a Ejecutar, luego de recibir el mundial de Visor de Teclado teclas de acceso rápido.

Aquí está el origen de la secuencia de comandos:

property theApplication : "KeyboardViewer"
property thePath : "/System/Library/Input Methods/KeyboardViewer.app"

set HFSPath to ((POSIX file thePath) as string)
tell application "System Events" to ¬
    set isRunning to 0 < (count (application processes whose name is theApplication))
if isRunning then
    tell application HFSPath to quit
else
    ignoring application responses
        tell application HFSPath to activate
    end ignoring
end if

Si KeyboardViewer se abre con un AppleScript o con open y la ventana principal está cerrada, el Visor de Teclado proceso permanece abierto y mantiene el uso acerca de 0-20% de la CPU.

Este sería también el trabajo después de la ventana principal ha sido cerrado, haciendo clic en el botón de cerrar:

if application "KeyboardViewer" is running then
    tell application "System Events" to number of windows of process "KeyboardViewer"
    if result is 0 then
        quit application "KeyboardViewer"
        delay 0.1
        launch application "KeyboardViewer"
    else
        quit application "KeyboardViewer"
    end if
else
    launch application "KeyboardViewer"
end if

Si el Visor de Teclado se abre con AppleScript o open -a KeyboardViewer y la ventana principal está cerrada, el proceso queda abierto y mantiene el uso acerca de 0-15% de la CPU. Esto no sucede cuando se selecciona Mostrar Visor de Teclado desde el menú de entrada. Por lo que la mejor opción podría ser que se haga clic en el elemento de menú:

tell application "System Events" to tell process "SystemUIServer"
    tell (menu bar item 1 where description is "text input") of menu bar 1
        click
        click (menu item 1 where title ends with "Keyboard Viewer") of menu 1
    end tell
end tell

Ambos scripts requieren de acceso para dispositivos de ayuda para ser habilitado en el panel de preferencias accesibilidad.