¿Cómo desplegar el flujo de trabajo de Automator en los clientes?

Si realmente quieres que el proceso sea "a prueba de idiotas", esta es la opción. En script Editor.app, crea un nuevo documento en blanco e inmediatamente ve y guárdalo como aplicación (yo guardé el mío como "JIMZ Attach Folder Action.app")

El propósito de esta aplicación sería copiar el archivo de flujo de trabajo de Automator (que se incluirá dentro de la carpeta "Recursos" de esta nueva aplicación que acabas de crear en scriptEditor ) que quieres que se adjunte a la carpeta "ABC" en el ordenador de cualquier usuario, a la carpeta "Folder Actions" necesaria en ese ordenador. Si la carpeta "ABC" no existe en el ordenador de destino, se creará. Para los fines de este proyecto, la ubicación de la carpeta "ABC" sería en el escritorio del ordenador de destino.

Pegue el siguiente código en su nueva aplicación AppleScript en blanco que acaba de crear.

property nameOfTriggerFolder : "ABC"
property pathToFolderActions : ((path to workflows folder as text) & "Applications:Folder Actions:")
property attachFolderActionTo : (path to desktop as text) & nameOfTriggerFolder

set resourceName to "ABC Folder Action.scpt"
set folderActionScript to ((path to me as string) & "Contents:Resources:" & resourceName) as string

tell application "Finder"
    if not (exists of folder attachFolderActionTo) then
        make new folder at (path to desktop) with properties {name:nameOfTriggerFolder}
    end if
    duplicate file folderActionScript to folder pathToFolderActions with replacing
end tell

tell application "Folder Actions Setup"
    activate
    try
        set addedFolderAction to make new folder action with properties {name:nameOfTriggerFolder, path:attachFolderActionTo}
    end try
    try
        delay 0.5
        tell addedFolderAction to make new script with properties {name:resourceName, path:(pathToFolderActions & resourceName)}
    end try
    if not folder actions enabled then
        set folder actions enabled to true
    end if
end tell

A continuación, siga adelante y arrastre su archivo de flujo de trabajo de Automator desde la aplicación Finder directamente a la carpeta de recursos en el editor de script (como se muestra en la animación siguiente)

Compila y guarda la aplicación en el editor de script. Ahora puedes distribuir esta app a quien quieras. Cuando esta aplicación se inicie en cualquier ordenador de destino, copiará el archivo de flujo de trabajo de Automator directamente a la carpeta donde debe ubicarse. También añadirá la carpeta "ABC" a la lista de carpetas habilitadas en el Folder Actions Setup.app y adjuntará el script o archivo de flujo de trabajo a esa carpeta

De forma similar a la sugerencia de @wch1zpink, yo consideraría formular el Carpeta Acción como un script en lugar de un Automatizador flujo de trabajo, que sería algo así:

on adding folder items to directory after receiving fs

    do shell script "..."

end adding folder items to

Guardando esto como un .scpt o .applescript y moverlo a ~/Library/Scripts/Folder Action Scripts , puedes entonces scribir la creación de acciones de carpeta y adjuntarlas a las carpetas así:

use sys : application "System Events"

property name : "abc"
property path : "/path/to/abc"
property folder action : a reference to folder action named (my name)
property script : "my folder action script.applescript"
property folder : a reference to Folder Action scripts folder
property file : a reference to the file named (my script) in my folder

set folder actions enabled to true

if not (my file exists) then return open my folder
if my folder action exists then return my folder action's scripts

make new folder action with properties {name:my name, path:my path}
tell my folder action to make new script with properties ¬
    {name:my file's name, POSIX path:my file's POSIX path}

set my folder action's enabled to true
set my folder action's scripts's enabled to true

donde "my folder action script.applescript" es el nombre de su acción de carpeta guardada script; y las propiedades name y path representan el nombre y la ruta de su carpeta supervisada.