¿Cómo copio múltiples archivos al portapapeles de macOS mediante programación?

Usted puede utilizar el AppleScript a continuación para crear una función bash que te permitirá añadir varios objetos de archivo en el portapapeles mediante el suministro de sus rutas de acceso de archivo como argumentos de línea de comandos. Devuelve true sobre el éxito y el false sobre el fracaso.

Usted no será capaz de pegar los elementos dentro de la terminal, pero si usted navegar a una ubicación en el Finder, puede pegar los elementos. Espero que esto sea a lo largo de las líneas de lo que fueron después.

use framework "Appkit"
use Finder : application "Finder"

property this : a reference to current application
property NSFileManager : a reference to NSFileManager of this
property NSImage : a reference to NSImage of this
property NSMutableArray : a reference to NSMutableArray of this
property NSPasteboard : a reference to NSPasteboard of this
property NSString : a reference to NSString of this
property NSURL : a reference to NSURL of this

property pb : missing value

on run input
    if input's class = script then set input to ¬
        Finder's selection as alias list

    init()
    clearClipboard()
    addToClipboard(input)
end run


to init()
    set pb to NSPasteboard's generalPasteboard()
end init

to clearClipboard()
    if pb = missing value then init()
    pb's clearContents()
end clearClipboard

to addToClipboard(fs)
    local fs

    set fURLs to NSMutableArray's array()
    set FileManager to NSFileManager's defaultManager()

    repeat with f in fs
        if f's class = alias then set f to f's POSIX path
        set fp to (NSString's stringWithString:f)'s ¬
            stringByStandardizingPath()
        if (FileManager's fileExistsAtPath:fp) then ¬
            (fURLs's addObject:(NSURL's fileURLWithPath:fp))
    end repeat

    if pb = missing value then init()
    pb's writeObjects:fURLs
end addToClipboard

Recomiendo guardar este script como .applescript o .scpt archivo en algún lugar de su máquina usando el Editor de secuencias de Comandos. A continuación, en el terminal, crear su función bash:

pbadd() {
    osascript "/Path/To/Saved AppleScript.scpt" "$@"
}

Entonces, para usar:

pbadd ~/Pictures/*.jpg
pbadd ~/Documents/Some\ file.pdf ~/Music/A\ Random\ Song.mp3