¿Cómo le digo al reproductor Quicktime que inicie una nueva grabación de película con una Apple script?

Habiendo duplicado su Reproductor QuickTime aplicación y lo llamó Reacción Entiendo que ha creado un applet de AppleScript y ha colocado esta copia de Reacción.app dentro del Resources del applet AppleScript.

Porque es un duplicado de Reproductor QuickTime (que se puede programar), Reacción también se puede programar, y también se puede programar desde el AppleScript del applet (ubicado en Resources/scripts/main.scpt ).

Su main.scpt debería ser algo así:

set A to path to resource "Reaction.app"

set home to POSIX path of (path to home folder)
set fp to home & "/Movies/Reaction Recording.mov"
set f to a reference to POSIX file fp

using terms from application "QuickTime Player"
    tell the application named A
        activate
        tell the (new movie recording)
            start
            delay 10
            pause
            save in f
            stop
            close
        end tell
    end tell
end using terms from

application "QuickTime Player" puede cambiar por sí mismo a application "Reaction" Lo cual está completamente bien.

Este script crea una grabación de ~10 segundos, menos un par de segundos para tener en cuenta la inicialización del script y demás. Cambiar delay 10 a cualquier valor que represente un tiempo de grabación razonable en segundos.

Para enviarla como archivo adjunto mediante Correo :

set msgSubject to "My Reaction Recording"
set msgBody to "Hi. Please see the attached recording. \n"
set msgFrom to "your@email.com"
set msgTo to "friend@email.com"

tell application "Mail"
    activate
    tell (make new outgoing message ¬
        with properties {visible:true ¬
        , subject:msgSubject ¬
        , content:msgBody ¬
        , sender:msgFrom})

        make new to recipient ¬
            at end of to recipients ¬
            with properties {address:msgTo}

        tell its content to make new attachment ¬
            at after the last paragraph ¬
            with properties {file name:f as alias}

        delay 2

        -- send
    end tell
end tell

La parte superior script y la parte inferior scriptpueden simplemente unirse para formar un script continuo. Es posible que necesites un retardo entre las dos porciones, pero en mi sistema no lo necesité.

Sin embargo, el retraso dentro del Correo es importante si desea enviar el correo electrónico (también debe descomentar el bloque send eliminando el comando -- (mantenerlo, lo que hice durante las pruebas, le permitirá previsualizar el correo electrónico y enviarlo manualmente).

Una forma rápida de conseguirlo sería enviar el atajo de teclado de tu script a la aplicación. Si no recuerdo mal, el atajo de teclado para iniciar la grabación de una nueva película en QuickTime Player es optioncommandN .

Por lo tanto, usted podría enviar esto a través de AppleScript añadiendo el siguiente código:

tell application "System Events"
    keystroke "n" using {option down, command down}
end tell

Obviamente, tendrás que hacer esto después de activar tu aplicación, o el atajo de teclado se aplicará a cualquier aplicación que esté activa en ese momento.

[ACTUALIZACIÓN]

Si desea también iniciar y detener la grabación, puede hacerlo pulsando la tecla space bar . Es decir, pulsando la tecla space bar iniciará la grabación, pulsándolo de nuevo se detendrá la grabación. Si necesita hacer esto dentro de su AppleScript, puede utilizar el código de la tecla AppleScript correspondiente (para el space bar son 49). Puede utilizar los códigos de las teclas con la siguiente sintaxis:

tell application "System Events"
  key code 49
end tell