Aplicación AppleScript como página web de Safari

Como han señalado otros usuarios, probablemente no merezca la pena mantener el tercer y cuarto punto, ya que dificulta la aplicación de los dos primeros:

use S : application "Safari"
property PHPMyAdminURL : "http://xxxxx/ppmya"

on run
    if S is not running then return openPHPMyAdmin()

    set _T to a reference to (every tab of every window of S whose ¬
        name contains "PHPMyAdmin" and ¬
        URL contains "/ppmya")

    if (count _T) > 0 then return viewPHPMyAdmin(_T)

    openPHPMyAdmin()
end run

to openPHPMyAdmin()
    tell S
        if (count windows) = 0 then
            make new document with properties ¬
                {URL:PHPMyAdminURL}
        else
            make new tab at end of tabs of S's window 1 ¬
                with properties ¬
                {URL:PHPMyAdminURL}
            set current tab of S's window 1 to the result
        end if

        activate
    end tell
end openPHPMyAdmin

to viewPHPMyAdmin(T)
    set [T] to T
    set W to the first window of S whose tabs contains T

    set current tab of W to T
    activate S
    set the index of W to 1
end viewPHPMyAdmin

Después de algunos comentarios iniciales de @user3439894, he eliminado el on quit handler ya que al intentar utilizar el script como una aplicación de permanencia impide que el punto 2 se implemente efectivamente.