¿Hay una manera de hacer una presentación de todos los videos y las imágenes contenidas en una sola carpeta?

1. Abra /Applications/Photos.app e ir a Archivo>Nuevo Álbum.
2. Crear un nuevo Álbum con el nombre de "Pantalla de la Tienda"
3. Abra /Applications/Utilities/Script Editor.app
4. Copiar y Pegar el siguiente Script
5. Vaya a Archivo>Exportar
   • Formato De Archivo: Aplicación
6. Abrir La Aplicación
7. Seleccione la carpeta que contiene las Fotos y los Videos
8. Haga Clic En Elegir
9. Celebrar!

Aquí está el código (editado por @wch1zpink) :

set imageNameExtensions to {"jpg", "jpeg", "png", "tiff", "bmp", "gif"}
set videoNameExtensions to {"mov", "mp4", "m4v", "avi"}
set nameExtensions to (videoNameExtensions & imageNameExtensions)

set myFolder to (choose folder) as text

set theChoice to display dialog ¬
    "Select Your Option" buttons {"Cancel", "Main Folder", "Main Folder And Sub-Folders"} ¬
    default button 3 ¬
    cancel button 1 ¬
    with title ¬
    "CHOOSE A FOLDER" giving up after 30

if button returned of theChoice is "Main Folder And Sub-Folders" then
    tell application "Finder"
        set mediaItems to (files of (entire contents of folder myFolder) ¬
            whose name extension is in nameExtensions) as alias list
    end tell
else if button returned of theChoice is "Main Folder" then
    tell application "Finder"
        set mediaItems to (files of (folder myFolder) ¬
            whose name extension is in nameExtensions) as alias list
    end tell
end if

tell application "Photos"
    import mediaItems into container named "Store Display" with skip check duplicates
    start slideshow using media items of album "Store Display"
end tell