¿Cómo puedo cambiar el nombre de los archivos de capturas de pantalla añadidos a mi carpeta de capturas de pantalla?

He utilizado Cocktail para especificar que las capturas de pantalla se guarden en una carpeta llamada "Screenshots" en mi Mac. Utilizo una aplicación llamada "Hazel" para vigilar esa carpeta y ejecutar automáticamente un AppleScript que muestra un cuadro de diálogo preguntando si quiero cambiar el nombre de la captura de pantalla.

Este es el cuadro de diálogo que aparece automáticamente:

Aquí hay una captura de pantalla de Hazel, con mi regla "Name it":

Al hacer clic en el botón de edición (lápiz) de esa ventana, se muestran las condiciones en las que se ejecutará la regla. Como puedes ver, Hazel ejecutará el AppleScript si el archivo es una imagen, añadida hoy, cuyo comentario NO contiene la palabra "Hazel". Dado que las capturas de pantalla recién hechas no tienen comentarios con la palabra "Hazel", estas son las condiciones correctas. (Cuando el script se ejecuta, añade al archivo un comentario con la palabra "Hazel").

Aquí está mi AppleScript.

tell application "System Events"
    set the_apps to every process whose frontmost is true
    set the_app to item 1 of the_apps
    set the_app_name to name of the_app
    set old_name to name of theFile
    set the_choice to display dialog "If you want to rename this file, do it" buttons {"Rename", "No thanks"} default button "Rename" default answer old_name
end tell

if the button returned of the_choice is "Rename" then
    set the_date_string to do shell script "date '+%Y.%m.%d'"
    tell application "Finder"
        set the comment of theFile to "Name changed with Hazel"
        set the_name to text returned of the_choice
        set cleaned_name to change " " into "_" in the_name
        set cleaned_name to the_date_string & "_" & cleaned_name
        if (characters 12 thru 13 of cleaned_name as string) is "wm" then
            move theFile to (POSIX file "/Users/cboyce/Dropbox/Screenshots/Webmaster Screenshots")
        else
            move theFile to (POSIX file "/Users/cboyce/Dropbox/Screenshots/Renamed Screenshots")
        end if
        set the name of theFile to cleaned_name & ".png"
    end tell
end if
tell application the_app_name to activate

La primera parte del script registra el nombre de la app más frontal en el momento de la creación de la captura de pantalla. También tiene el paso "Display Dialog".

La segunda parte del script renombra la captura de pantalla y la mueve a una carpeta de "Capturas de pantalla renombradas". Si pongo "wm" al principio del nuevo nombre del archivo, el script pone la captura de pantalla renombrada en una carpeta especial de "Capturas de pantalla del webmaster". El script también sustituye los espacios por guiones bajos, pero usted no tendría que incluir esa parte. Observe también que el script establece el comentario de la captura de pantalla como "Nombre cambiado con Hazel". Por supuesto puedes hacer tus propias condiciones pero esto me funciona.

Tendrás que cambiar el nombre de usuario en el script, en las dos líneas que empiezan por "move theFile". Sustituye "cboyce" (mi nombre de usuario) por el que sea el tuyo. Si no estás seguro de cuál es el tuyo, busca la carpeta Users en el nivel superior del disco duro de tu Mac, ábrela y busca la carpeta con el icono de la casa. El nombre de esa carpeta es el nombre de usuario. En realidad, tienes que cambiar toda la ruta. Yo estoy guardando mis capturas de pantalla renombradas en carpetas guardadas en mi carpeta de Dropbox, pero por supuesto puedes ponerlas donde quieras. Así que cambia la ruta en esas líneas de "mover elArchivo" para que apunte a TUS carpetas.

Hazel es un software comercial, pero puedes utilizarlo en modo Demo de forma gratuita. El modo Demo te permite ver sólo una carpeta, que en tu caso es todo lo que necesitas. Puedes descargar Hazel desde Noodlesoft.com .

Puedes intentar usar la aplicación Grab. Viene con el software de tu sistema y se almacena en la carpeta Utilidades. Puedes utilizar Grab para hacer una captura de pantalla, y luego hacer clic en el elemento de menú Archivo y elegir Guardar. Esto te permitirá nombrar el archivo y seleccionar la carpeta para almacenar la captura de pantalla.

Puedes crear un Servicio con Automator.app, al que puedes asignar un acceso directo en las Preferencias de Servicios (incluso los existentes pueden sobrescribirse).

Abra Automator, seleccione Servicio como tipo de documento, seleccione en la parte superior de la ventana: El servicio no recibe ninguna entrada en ninguna aplicación . Acción de doble clic Ejecutar AppleScript o arrastrarlo a la mitad derecha de la ventana e insertar el siguiente script:

set destFolder to "/Path/to/the/Folder/" --insert here path to Screenshot folder

set screenshotName to text returned of (display dialog "Screenshot" default answer "")
set destFile to destFolder & screenshotName & ".png"

---------------------------------------
-- give a warning in case file is already existing
try
alias (POSIX file destFile)
set _exists to true
repeat until _exists is false
try
set screenshotName to text returned of (display dialog "Filename is already existing!" default answer "")
alias (POSIX file (destFolder & screenshotName & ".png"))
on error
set _exists to false
    end try
end repeat
set destFile to destFolder & screenshotName & ".png"
end try

---------------------------------------------

do shell script "screencapture -io " & quoted form of destFile

(*
--------------------------
screencapture:
-i = Capture screen interactively
-o = In window capture mode, do not capture the shadow of the window
--------------------------
*)

Asegúrate de insertar la ruta de tu carpeta de capturas de pantalla en la primera línea.

El script no cambiar el nombre de ... pero primero establece el nombre y entonces crea la captura de pantalla.

Para acceder rápidamente a las "Preferencias de Servicios", haga clic en el nombre del programa actualmente activo en la barra de menús (por ejemplo, Safari) y seleccione "Preferencias de Servicios" en la opción de menú "Servicios". Busque allí su servicio creado y añada un acceso directo a él... por ejemplo cmd-ctrl-5