Alias - "Mostrar el original" en una nueva pestaña

Busqué por ahí y encontré un applescript (que se puede convertir en un acceso directo) que hace justo lo que quieres. Desafortunadamente, no es súper simple como debería ser. Sin embargo, es mejor que nada, y sólo tienes que hacerlo una vez. Te ahorrará tiempo a largo plazo.

1) Abra Automator.

2) Crear un nuevo "Servicio

3) Establecer el servicio recibe a "ninguna entrada" en "Finder

4) añadir "Ejecutar applescript

5) Poner este código en su interior:

-- duplicateFinderTab.scpt
-- Uses a hacky workaroud to duplicate the frontmost Finder tab,
-- since Apple hasn't provided great AppleScript support for this.

----------------------------------------------
on run {}
    tell application "Finder"
        if (count of Finder windows) > 0 then set duplicate_me to target of front Finder window
        set _sel to the selection
    end tell

    new_tab()

    tell application "Finder"
        set target of front Finder window to duplicate_me
        select _sel
    end tell

    open_orig()

end run

----------------------------------------------
on new_tab()
    tell application "System Events" to tell application process "Finder"
        set frontmost to true
        tell front menu bar to tell menu "File" to tell menu item "New Tab"
            perform action "AXPress"
        end tell
    end tell
end new_tab
----------------------------------------------
on open_orig()
    tell application "System Events" to tell application process "Finder"
        set frontmost to true
        tell front menu bar to tell menu "File" to tell menu item "Show Original"
            perform action "AXPress"
        end tell
    end tell
end open_orig

6) guárdalo (si abres una ventana del finder, y tienes tu alias seleccionado, entonces vuelve a automator y dale a 'ejecutar', entonces funcionará en este punto) -- Nota: puede que te pida que añadas 'Automator' a los permisos de 'Preferencias del Sistema' -> 'Seguridad y Privacidad' -> 'Accesibilidad'.

7) en las preferencias del sistema, vaya a "teclado" -> "accesos directos" -> "servicios" -> "cualquiera que sea su nombre" elija un acceso directo (como "^-CMD-O").

Otras cosas:

Es posible que tenga que hacerlo una vez:

cuando se selecciona el buscador, en el menú,

Buscador' -> 'Servicios' -> 'como sea que lo hayas nombrado'

o si no aparece:

'Finder' -> 'Servicios' -> 'Preferencias de servicios..' -> marque la casilla en las preferencias del sistema que su aplicación se llama

Hay otros errores de permiso que puede recibir dependiendo de cómo está configurado su sistema, sin embargo, usted debe notar que el script funciona cuando se pulsa 'ejecutar' en el paso 6 o después del paso 5. Sólo tienes que seleccionar primero el archivo en el buscador y luego cambiar a la aplicación del automatizador y pulsar 'ejecutar'.

Y si todo te ha funcionado sin problemas, el atajo cmd-cntl-O debería funcionarte, así que puedes hacer ese atajo, (que abre una nueva pestaña de la misma selección), y luego hacer clic con el botón derecho y seleccionar 'mostrar original'

Editado por OP
Si recibe un error "com.automator.runner.xpc no tiene permitido el acceso asistido", la solución no es obvia.
No se puede añadir el propio com.automator.runner.xpc a Assistive Access, ni tampoco ayuda añadir Automator o Automator Runner, sin embargo después de un reinicio la pista era que se disparaban dos errores, no sólo uno.

Añadir el propio Finder a Assistive Access permitía ejecutar el script.

Una solución mucho más corta y limpia sin scripts de UI:

Abrir Automator, crear un nuevo Servicio, aceptar archivos y carpetas del Finder, añadir un Ejecutar AppleScript acción y escriba lo siguiente:

on run {input, parameters}
    repeat with aFile in input
        tell application "Finder"
            try
                set origFile to original item of aFile
                set aWindow to make new Finder window
                set aWindow's target to origFile's parent
                select origFile
            end try
        end tell
    end repeat
end run

Su pantalla debería tener un aspecto similar al siguiente:

Guarde el servicio de Automator como Revelar en una nueva ventana y luego abrir Preferencias del Sistema / Teclado / Atajos / Servicios . Encuentre el Revelar en una nueva ventana servicio, haga clic en Añadir acceso directo y escriba R . Su pantalla debería tener un aspecto similar al siguiente:

Cierre y pruebe el servicio en Finder seleccionando uno o varios alias y pulsando el acceso directo elegido R . Funciona con múltiples archivos, carpetas y puede realizar el Reveal incluso si algunos de los elementos no son realmente alias (de ahí el try/end try en el script).