¿Añadir nombres de archivos adjuntos al sujeto en mi guión de Apple?

Simplemente cambia esta línea:

    set MailSubject to fileAliases

a esto:

    set mailSubject to fileAliases as string

    tell application "Finder" to get insertion location
    set text item delimiters of AppleScript to result

    set mailSubject to rest of text items of mailSubject

ADDENDUM:

Espero que no se olvide de mi observación de que el script que presenta en su pregunta contiene un montón de código redundante y/o mal formado. Funciona muy bien, por lo que no es de gran importancia más allá de la estética. Sin embargo, un script más ordenado y bien formado facilita la identificación de errores y, en el caso de los script más largos que realizan más tareas, se ejecutarán de forma más eficiente/rápida.

Así que, con esto en mente, me tomé la libertad de reescribir tu script, que espero que pueda ser útil como una herramienta de aprendizaje, o simplemente ser más fácil de llevar a cabo si quieres hacer más cambios por ti mismo.

    property mailSubjectPrefix : "Datei(en) für dich: "
    property subjAttNameSeparator : ", "
    property attachSeparator : "*******"
    property attachPrefix : "Anhänge:"

    set theSubject to "Datei(en): "
    set theContent to "Datei(en) für dich:\n\n"
    set recipientAddress to "mail@mail.com"

    -- Get the selection of the frontmost Finder window
    -- as a list of aliases
    tell application "Finder"
        set fileAliases to the selection as alias list
        set text item delimiters of AppleScript to insertion location
        set fileNames to rest of text items of (fileAliases as text)
    end tell

    -- Check if the selection is not empty
    if the number of fileAliases is 0 then return beep

    -- Now talk to mail to create the message
    tell application "Mail"
        set text item delimiters of AppleScript to subjAttNameSeparator
        tell (make new outgoing message at beginning ¬
            with properties {content:theContent, visible:true, subject:mailSubjectPrefix & (fileNames as string)})

            -- Add the recipient
            make new to recipient at end with properties {address:recipientAddress}

            -- Attach all the selected files
            repeat with fileAlias in fileAliases
                make new attachment with properties {file name:fileAlias} at after the last paragraph
            end repeat

        end tell

        -- Put Mail in the foreground
        activate
    end tell

Si tiene alguna duda que necesite aclaración sobre algún punto, no dude en dejar un comentario y me pondré en contacto con usted.