Hacer que Safari cargue las pestañas de fondo

No conozco ninguna forma de alterar el comportamiento por defecto de Safari, pero esta tarea puede automatizarse con bastante facilidad si se dispone de un medio para ejecutar un AppleScript.

Yo uso FastScripts y Maestro del teclado para poder asignar atajos de teclado globales o específicos de la aplicación a mis numerosos scripts.

Este AppleScript recargará todas las pestañas de la ventana principal de Safari.

----------------------------------------------------------------
# Auth: Christopher Stone
# dCre: 2011/08/09 20:33
# dMod: 2015/11/14 16:46
# Appl: Safari
# Task: Reload Every Tab in front window.
# Libs: ELb
# Osax: None
# Tags: @Applescript, @Safari, @Reload, @Tabs, @Front, @Window
----------------------------------------------------------------

try

   tell application "Safari"

      set tabList to tabs of front window

      repeat with theTab in tabList
         tell theTab to do JavaScript "location.reload(true)"
      end repeat

   end tell

on error e number n
   stdErr(e, n, true, true) of me
end try

----------------------------------------------------------------
--» HANDLERS
----------------------------------------------------------------
on stdErr(e, n, beepFlag, ddFlag)
   set e to e & return & return & "Num: " & n
   if beepFlag = true then
      beep
   end if
   if ddFlag = true then
      if n ≠ -128 then
         try
            tell application (path to frontmost application as text) to set ddButton to button returned of ¬
               (display dialog e with title "ERROR!" buttons {"Copy Error Message", "Cancel", "OK"} ¬
                  default button "OK" giving up after 30)
            if ddButton = "Copy Error Message" then set the clipboard to e
         end try
      end if
   else
      return e
   end if
end stdErr
----------------------------------------------------------------

En mi sistema le he dado un atajo de teclado de ⌃⇧⌘R que es una buena mnemotecnia para mí.

Es bastante fácil alterar el script para recargar cada pestaña en cada ventana.

----------------------------------------------------------------------------
# Auth: Christopher Stone
# dCre: 2011/08/09 20:33
# dMod: 2011/08/09 20:57
# Appl: Safari
# Task: Reload Every Tab in Every Window.
# Libs: None
# Osax: None
# Tags: @Applescript, @Reload, @Tabs, @Every, @Window
----------------------------------------------------------------------------

tell application "Safari"

    set tabList to tabs of windows

    repeat with theWindow in tabList
        repeat with theTab in theWindow
            tell (theTab's contents)
                do JavaScript "location.reload(true)"
            end tell
        end repeat
    end repeat

end tell

----------------------------------------------------------------------------

Lo uso tan raramente que no le he dado un atajo de teclado y tengo que activarlo manualmente desde el menú de FastScripts. (Esto es también una salvaguarda para evitar que pulse una tecla de acceso rápido por accidente y tenga que esperar a que se recargue cada pestaña).

-ccs