¿Cómo cambiar el idioma de la ortografía en OS X con AppleScript?

El AppleScript código, a continuación, emplea la interfaz de usuario de secuencias de comandos y porque un menú emergente que está involucrado, las Preferencias del Sistema estará visible (activate) durante el proceso. Había un menú emergente que no se han involucrado, esto se podría haber hecho sin necesidad de hacer visible.

Dicho esto, técnicamente se puede hacer sin hacer la ventana principal visible, pero luego todo lo que se ve es el menú emergente flash por un momento en la pantalla. Como esto puede ser más de un disgusto, preguntándose qué sólo brilló en la pantalla, mostrando todo el Sistema de Preferencias de la ventana, es probablemente menos de una molestia. Usted puede ver la diferencia y probarlo por comentar activate, por ejemplo -- activate, y elegir el que prefieras.

El AppleScript código hace lo siguiente:

• Abre Preferencias del Sistema para: Teclado > Texto
• Cambia el idioma en la Ortografía: menú emergente que se basa en lo siguiente:
  • Si se establece en Automático por el Lenguaje, cambia a inglés de Estados Unidos.
  • Si se establece en el inglés de Estados Unidos, los cambios que se Türkçe.
  • Si se establece a Türkçe, cambia a inglés de Estados Unidos.
• Cierra Las Preferencias Del Sistema.

Esencialmente, una vez que no está establecido en Automático por el Lenguaje, entonces, se alterna entre el inglés de Estados Unidos y Türkçe. cada vez que se ejecute.

Puede guardar esto como un AppleScript aplicación, colocarlo en el Docky, cada vez que se hace clic en él se alterna entre los dos idiomas. _{(Una vez que el primer set a uno de los idiomas).}

Nota: Guarda un AppleScript aplicación tendrá que ser añadido a Preferencias del Sistema > Seguridad Y Privacidad > Privacidad > Accesibilidad, la adición de la aplicación para que el Permitir que las aplicaciones siguientes para controlar el equipo de la lista.

Esto también se podría hacer en un Automator de servicio, donde un atajo de teclado podría ser asignado. (Vea las instrucciones al final de esta respuesta.)

Nota: El siguiente AppleScript Código ha sido probado en OS X El Capitan 10.11.6 y puede necesitar ser revisado para su uso con otras versiones de OS X/macOS.

AppleScript Código:

tell application "System Preferences"
    activate
    reveal anchor "Text" of pane id "com.apple.preference.keyboard"
    delay 0.5
    tell application "System Events"
        tell pop up button 3 of tab group 1 of window 1 of application process "System Preferences"
            if (value) is "U.S. English" then
                click
                click menu item "Türkçe" of menu 1
            else if (value) is "Türkçe" then
                click
                click menu item "U.S. English" of menu 1
            else if (value) is "Automatic by Language" then
                click
                click menu item "U.S. English" of menu 1
            end if
        end tell
    end tell
    quit
end tell

Nota: Debido a IU de secuencias de comandos puede ser a veces depende de la fecha de cosas, el valor de la delay comando puede ser necesario ajustar y / o adicional delay comandos puede ser necesario añadir como/si es necesario cuando se ejecuta en su sistema. Hacer los cambios pertinentes.

También, si usted quiere hacer es algo que siempre alternar entre los dos idiomas, ya que establece que uno o el otro, en circunstancias normales, usted puede quitar de las siguientes líneas de código de la if bloque de instrucción en la secuencia de comandos:

else if (value) is "Automatic by Language" then
    click
    click menu item "U.S. English" of menu 1

Para utilizar este AppleScript código como un Automator Servicio, haga lo siguiente:

• En Automator, seleccione: Archivo > Nuevo > Servicio de
• Conjunto: el Servicio no recibe ninguna entrada en cualquier aplicación
• Añadir un Ejecutar AppleScript Acción.
  • Elimine las líneas que contengan (* Your script goes here *) y return input.
  • Pegar en el AppleScript código dentro de la on run de controlador.
• Guardar el Automator Servicio, dándole un nombre apropiado, por ejemplo: Alternar la Ortografía del Idioma

En Preferencias del Sistema > Teclado > accesos directos > Servicios > (Nombre Que le Dio El "Servicio"), usted puede agregar el atajo de teclado para desencadenar este servicio.