¿Cómo aumentar el tamaño del cursor mediante programación?

Por desgracia, la línea de comando defaults, que puede read e o write el valor de la mouseDriverCursorSizeclave en lacom.apple.universalaccess .plist archivo, el write comando, por ejemplo defaults write com.apple.universalaccess mouseDriverCursorSize 2.5 no toma efecto inmediato, y de hecho puede ser sobreescritos antes de que el cambio surta efecto. Nota: El mouseDriverCursorSize clave en com.apple.universalaccess .plist archivo no existe, a menos que el valor predeterminado previamente ha sido cambiado.

Mientras que usted dijo que usted no quiere ir a la GUI de la ruta, por ejemplo, con AppleScript, acerca de cómo dividir la diferencia y lo hacen desde la línea de comandos usando osascript para proceso de la AppleScript código, que hace que el cambio de Preferencias del Sistema, pero sin ser interrumpido por el Sistema de Preferencias de la interfaz de usuario. Como cuestión de hecho, suponiendo que el Sistema de Preferencias Muelle de Teja todavía está presente, como es su defecto, todas las que usted verá es el Sistema de Preferencias del Dock de Baldosas de rebote una vez, y no el Sistema de Preferencias de la interfaz de usuario. (Esto supone que no estaba abierta, para empezar.)

Si eso es aceptable, entonces el siguiente AppleScript código se guarda como un ejecutable de línea de comandos para hacer el trabajo:

• Nota: El valor que se muestra para theCursorSize es lo que mi sistema es en la actualidad.

#!/usr/bin/osascript

    -- # set theCursorSize between 1.0 and 4 (Valid intermediate values may run out 12 decimal places.)

set theCursorSize to 1.388884782791

    -- # Get the system minor version number, as an integer.

set theSystemVersion to system version of (system info)
set TID to AppleScript's text item delimiters
set AppleScript's text item delimiters to {"."}
set theMinorSystemVersion to text item 2 of theSystemVersion as integer
set AppleScript's text item delimiters to TID

    -- # Change the size of the mouse cursor.

tell application "System Preferences"
    reveal anchor "Seeing_Display" of pane id "com.apple.preference.universalaccess"
    delay 0.5   -- # Modify as/if necessary. Value is in seconds as a decimal number.
    tell application "System Events"
        if theMinorSystemVersion is equal to 8 then
            set value of value indicator 1 of slider 2 of group 1 of window "Accessibility" of application process "System Preferences" to theCursorSize
        else if theMinorSystemVersion is equal to 9 then
            set value of value indicator 1 of slider 2 of window "Accessibility" of application process "System Preferences" to theCursorSize
        else if theMinorSystemVersion is greater than 9 and theMinorSystemVersion is less than 13 then
            set value of value indicator 1 of slider 1 of window "Accessibility" of application process "System Preferences" to theCursorSize
        end if
    end tell
    quit
end tell

Nota: Según su código, este script funciona con OS X 10.8 a través de macOS 10.12. No he probado esta bajo macOS Alta de la Sierra, sin embargo, si nada ha cambiado entre macOS 10.12 y macOS 10.13 , con este objeto, entonces el less than 13 then segmento de código puede ser cambiado a less than 14 then, o si se prefiere, acortar la línea de código justo:

else if theMinorSystemVersion is greater than 9 then

Para crear un ejecutable de línea de comandos, que contiene AppleScript código, haga lo siguiente en la Terminal:

touch cmcs
open cmcs

• Copiar y pegar el anterior AppleScript código en el abierto cmcs documento.
• Establecer el valor de theCursorSize a su preferido tamaño del cursor.
• Guardar el documento, pulsando: ⌘S

De vuelta en la Terminal, hacer cmcs ejecutable:

chmod u+x cmcs

Ahora el cmcs ejecutable de línea de comandos se puede ejecutar, escriba: ./cmcs

• Nota: Si coloca el cmcs ejecutable de línea de comandos en un lugar definido dentro de la PATH variable de entorno, se puede omitir el líder ./, y / o tener que escribir /path/to/cmcs. También tenga en cuenta que la nomenclatura de, cmcs es para cambiar el cursor del ratón de tamaño, y puede ser lo que usted desea ser de otra manera.

Notas Adicionales:

El valor de mouseDriverCursorSize clave en la com.apple.universalaccess .plist se almacena el archivo de redondeado a la 6ª posición decimal, e.g, 1.388884782791 se guarda como 1.388885

Para obtener el máximo valor, en el Editor de secuencias de Comandos, ejecute el siguiente script:

set theSystemVersion to system version of (system info)
set TID to AppleScript's text item delimiters
set AppleScript's text item delimiters to {"."}
set theMinorSystemVersion to text item 2 of theSystemVersion as integer
set AppleScript's text item delimiters to TID

tell application "System Preferences"
    reveal anchor "Seeing_Display" of pane id "com.apple.preference.universalaccess"
    delay 0.5 -- # Modify as/if necessary. Value is in seconds as a decimal number.
    tell application "System Events"
        if theMinorSystemVersion is equal to 8 then
            get value of value indicator 1 of slider 2 of group 1 of window "Accessibility" of application process "System Preferences"
        else if theMinorSystemVersion is equal to 9 then
            get value of value indicator 1 of slider 2 of window "Accessibility" of application process "System Preferences"
        else if theMinorSystemVersion is greater than 9 and theMinorSystemVersion is less than 13 then
            get value of value indicator 1 of slider 1 of window "Accessibility" of application process "System Preferences"
        end if
    end tell
    quit
end tell

Actualización para solucionar comentario:

Si estás queriendo ejecutar este cada vez que un Usuario inicia sesión enla que me gustaría hacer lo siguiente:

En Automator crear un nuevo flujo de trabajo de Aplicación y añadir un Ejecutar AppleScript acción .

En el Ejecutar AppleScript acción, reemplace (* Your script goes here *) y return input con todos, pero el shebang (#!/usr/bin/osascript) de la primera AppleScript código. El proceso no es necesario ya que este se ejecuta en un Ejecutar AppleScript acción frente a Ejecutar el Shell Script de acción.

Guardar el Automator Aplicación de flujo de trabajo como por ejemplo, Establecer Cursor del Ratón de Tamaño en los /las Aplicaciones de la carpeta.

En Preferencias del Sistema, haga dos cosas...

• En Usuarios Y Grupos > seleccione destino de Usuario > Elementos de inicio de Sesión y agregar Conjunto de Ratón de Tamaño del Cursor a la lista de Elementos de inicio de Sesión.

• En Seguridad Y Privacidad > Privacidad > Accesibilidad, agregar Set Cursor del Ratón de Tamaño al Permitir que las aplicaciones siguientes para controlar el equipo de la lista.

  • Nota: el anterior es para OS X 10.9 o posterior. Para OS X 10.8, Accesibilidad y comprobar el Permitir el acceso para dispositivos de ayuda casilla de verificación.

A continuación, cada vez que el Usuario se registra enel Conjunto del Cursor del Ratón de Tamaño va a ejecutar y hacer como programado.