Copiar el original cuando se arrastra un alias

He creado un pequeño AppleScript para usted. Si utiliza el Editor de secuencias de Comandos para guardarlo como un applet se puede arrastrar y soltar carpetas. La secuencia de comandos preguntará por la carpeta de destino y, a continuación, analizar el caído carpetas para cualquier alias contenidos. Si encuentra alguno va a copiar el original de los elementos a la carpeta de destino especificada.

Aquí está el código:

on open droppedItems
    try
        set destinationFolder to choose folder with prompt "Select destination folder:"
    on error
        return
    end try

    repeat with itemCount from 1 to length of droppedItems
        set theFolder to item itemCount of droppedItems

        tell application "Finder"
            if folder (theFolder as string) exists then
                set folderItems to list folder theFolder without invisibles

                repeat with folderItemCount from 1 to length of folderItems
                    set filename to (item folderItemCount of folderItems)
                    set theAlias to ((theFolder as text) & filename) as alias
                    try
                        set originalFile to original item of theAlias -- is Finder alias?
                        duplicate originalFile to destinationFolder
                    on error
                        display dialog (theAlias as string) & " doesn't seem to be an alias. Skipping."
                    end try
                end repeat
            else
                display dialog (theFolder as string) & "is not a folder. Skipping."
            end if
        end tell
    end repeat
end open

No es ni bonita ni la función completa, sino más bien la intención de mostrar un posible camino a seguir. I. e. no atravesar cualquier subcarpetas. También, no hay ninguna comprobación de la existencia del archivo antes de copiar. De todos modos, todavía puede ser lo que usted necesita. Divertirse!