Cambio automático de la configuración al conectar el ratón

En MacOS Sierra Si sólo tiene un Ratón USB no uno que venga con su propio software y sea multifunción con botones adicionales, etc., entonces en Preferencias del sistema > Ratón tiene los siguientes ajustes que se pueden cambiar:

• Dirección de desplazamiento: natural casilla de verificación
• Velocidad de seguimiento deslizador
• Velocidad de desplazamiento deslizador
• Velocidad de doble clic deslizador

Y dos ajustes adicionales en Ratón que no se abordará, por dos razones, la Botón principal del ratón: botones de radio si es otro entonces el por defecto de Izquierda es muy probable que ya esté fijado y que no cambie necesariamente porque se quiera cambiar el Dirección de desplazamiento: natural casilla de verificación y ya que el OP declaró Ratón USB asumo que no está usando Bluetooth y puede ignorar el Configurar el ratón Bluetooth... botón .

Esta respuesta va a utilizar AppleScript para obtener el antes de y después de ajustes para el valor de la mencionada lista deslizadores que se utilizará en el AppleScript código que sigue después de esto código .

Abrir Script Editor y crea un nuevo documento, luego añade lo siguiente código :

tell application "System Preferences"
    set current pane to pane id "com.apple.preference.mouse"
    --delay 0.5 -- # If necessary, uncomment 'delay' command and set its value in seconds and or decimal fractions there of.
    tell application "System Events"
        log "Scrolling speed is set to: " & value in (get properties of slider 1 of front window of application process "System Preferences")
        log "Double-Click speed is set to: " & value in (get properties of slider 2 of front window of application process "System Preferences")
        log "Tracking speed is set to: " & value in (get properties of slider 3 of front window of application process "System Preferences")
    end tell
end tell

Habrá dos diferencias afirma de la Dirección de desplazamiento: natural casilla de verificación en Preferencias del sistema > Ratón , comprobado y No se ha comprobado y el cambio en deslizador ajustes entre los dos afirma .

El código se ejecutará una vez para obtener el valor ajustes de la deslizadores . A continuación, realice los cambios de configuración que desee en el deslizadores para lo contrario estado de lo que era cuando se reunió el valores de los primeros ajustes para la primera estado . A continuación, ejecute el código de nuevo para obtener la configuración del diferencial.

A continuación, conectará el valores , reunidos arriba, en el código abajo. Usted puede comentario o eliminar cualquier deslizador que no va a ser cambiado por el código abajo.

El comentarios en el código a continuación debería ser suficiente, sin embargo, no dude en preguntar si necesita alguna explicación.

He guardado lo siguiente AppleScript código en Script Editor como una aplicación llamada Cambiar la configuración del ratón en el Aplicaciones carpeta.

Cuando se ejecuta, se activa el estado de la Dirección de desplazamiento: natural casilla de verificación entre comprobado y No se ha comprobado junto con el deslizador ajustes bajo cada estado .

AppleScript código para el Cambiar la configuración del ratón app:

on run
    try
        tell application "System Preferences"
            set current pane to pane id "com.apple.preference.mouse"
            -- delay 0.5    -- # If necessary, uncomment 'delay' command and set its value in seconds and or decimal fractions there of.
            tell application "System Events"
                set isChecked to get value of checkbox 1 of front window of application process "System Preferences" as boolean
                if isChecked then
                    --  # The 'Scroll direction: Natural' checkbox is checked, uncheck it.
                    set cbValue to value of (click checkbox 1 of front window of application process "System Preferences") as boolean
                    --  # Scrolling Speed - Valid Values: 0.0 to 8.0
                    set value of slider 1 of front window of application process "System Preferences" to 6.0
                    --  # Double-Click Speed - Valid Values: 0.0 to 10.0
                    set value of slider 2 of front window of application process "System Preferences" to 8.0
                    --  # Tracking Speed - Valid Values: 0.0 to 9.0
                    set value of slider 3 of front window of application process "System Preferences" to 6.0
                else
                    --  # The 'Scroll direction: Natural' checkbox is not checked, check it.
                    set cbValue to value of (click checkbox 1 of front window of application process "System Preferences") as boolean
                    --  # Scrolling Speed - Valid Values: 0.0 to 8.0
                    set value of slider 1 of front window of application process "System Preferences" to 4.5
                    --  # Double-Click Speed - Valid Values: 0.0 to 10.0
                    set value of slider 2 of front window of application process "System Preferences" to 8.0
                    --  # Tracking Speed - Valid Values: 0.0 to 9.0
                    set value of slider 3 of front window of application process "System Preferences" to 4.0
                end if
            end tell
            tell me
                if cbValue then
                    display notification "Natural scrolling is now active." with title (name of me)
                else
                    display notification "Natural scrolling is no longer active." with title (name of me)
                end if
            end tell
            quit
        end tell
    on error eStr number eNum
        activate
        display dialog eStr & " number " & eNum buttons {"OK"} default button 1 with title "Toggle Mouse Settings" with icon caution
        tell application "System Preferences" to quit
        return
    end try
end run

Nota: Antes de ejecutar el Cambiar la configuración del ratón aplicación, tendrás que añadirlo a: Preferencias del sistema > Seguridad y privacidad > Privacidad > Accesibilidad

Hay una aplicación llamada EventScripts que podría ser utilizado para disparar cuando un dispositivo USB se conecta y o se retira. No lo he utilizado antes, sólo sé que existe.

También hay una aplicación llamada Inversor de desplazamiento . No lo he utilizado antes, sólo sé que existe.